如何仅计算自定义函数中的可见单元格（根据单元格颜色计算单元格）

Question

我正在使用我在网上找到的自定义函数。它完成了我需要它做的事情 - 计算一系列单元格中特定颜色的单元格。

如何编辑它以仅计算可见单元格？ 我曾尝试使用它，但它没有任何作用。

For Each rCell In CountRange.SpecialCells(xlCellTypeVisible)

完整的功能是这样的：

    Function GetColorCount(CountRange As Range, CountColor As Range, Optional VolatileParameter As Variant)
Dim CountColorValue As Integer
Dim TotalCount As Integer
CountColorValue = CountColor.Interior.ColorIndex
Set rCell = CountRange
For Each rCell In CountRange
  If rCell.Interior.ColorIndex = CountColorValue Then
    TotalCount = TotalCount + 1
  End If
Next rCell
GetColorCount = TotalCount
End Function

要在工作表中使用它，然后输入：

=GetColorCount(A1:G20,H1, NOW())

地点：

• A1:G20 是我要统计所有黄色单元格的范围
• H1 是显示计数的单元格，颜色为黄色
• NOW() 让它在每次在范围内进行更改时运行 (??)

有什么建议吗？

Answer 1

Function GetColorCount(CountRange As Range, CountColor As Range, Optional VolatileParameter As Variant)
 Dim ColVal As Long, rCell As Range
 Dim TotalCount As Long
 ColVal = CountColor.Interior.ColorIndex
    For Each rCell In CountRange.Cells
      If rCell.Interior.ColorIndex = ColVal Then
          If rCell.EntireRow.Hidden = False And _
              rCell.EntireColumn.Hidden = False Then
              TotalCount = TotalCount + 1
          End If
      End If
    Next rCell
 GetColorCount = TotalCount
End Function

SpecialCells 不能在 UDF 中使用，但可以检查范围可见性中的每个单元格...

Answer 2

SpecialCells 在像这样包裹在 UDF 中时确实是片状的。

这是通过检查行高和列宽为零的解决方案/解决方法。我确定其他人存在，但这是实现目标的一种方式。

Function GetColorCount(CountRange As Range, CountColor As Range, Optional VolatileParameter As Variant)
    Dim CountColorValue As Integer
    Dim TotalCount As Integer
    CountColorValue = CountColor.Interior.ColorIndex
    For Each rcell In CountRange.Cells
        If rcell.Interior.ColorIndex = CountColorValue Then
            If (rcell.EntireRow.Height * rcell.EntireColumn.Width) <> 0 Then
                TotalCount = TotalCount + 1
            End If
        End If
    Next rcell
    GetColorCount = TotalCount
End Function