如何创建字典嵌套字典？答案

【问题标题】：How to create a dictionary nested dictionaries?如何创建字典嵌套字典？
【发布时间】：2021-02-14 01:46:34
【问题描述】：

我有一个字典，我想用它来存储带有字典的键作为值。本质上，使用我的数据表的以下屏幕截图，我希望字典（在 json 视图中）为：

{'Folder/PU01': {'PLCName':'PLCCC', 'DeviceName': 'fasasd', 'Description': '', '....'}
{'Folder/PU02': {'PLCName':'', 'DeviceName': '', 'Description': '', '....'}
etc...

我有下面的代码，它基本上是在创建它，但是 Next 上方的最底线是它出错的地方udtInstancesCurrent.Add deviceTagPath, udtInstanceParamsCurrent 这是将 udtInstanceParamsCurrent 字典分配给 udtInstanceCurrent 键，但因为它是对字典的引用而不是副本，所以它会在下一次循环时被覆盖。

我的问题是：如何将udtInstanceCurrent 中的字典键的值设置为udtInstanceParamsCurrent 字典的副本而不是对原始字典的引用？

Dim udtInstancesCurrent As Scripting.Dictionary
Dim udtInstanceParamsCurrent As Scripting.Dictionary
    
Set udtInstancesCurrent = New Scripting.Dictionary
Set udtInstanceParamsCurrent = New Scripting.Dictionary
'''' SAVE PARAMETER VALUES ''''
' For each udt instance tag path, add its param value into a dictionary to save its values
For Each udtTagPathCell In Range(.Cells(INSTANCES_ROW_HEADERS + 1, INSTANCES_COL_UDTTAGPATH), .Cells(INSTANCES_ROW_HEADERS, INSTANCES_COL_UDTTAGPATH).End(xlDown))
    udtTagPath = udtTagPathCell.Value
    deviceName = .Cells(udtTagPathCell.Row, INSTANCES_COL_DEVICENAME)
    deviceParentPath = .Cells(udtTagPathCell.Row, INSTANCES_COL_DEVICEPARENTPATH)
    deviceTagPath = deviceParentPath & "/" & deviceName
    Row = udtTagPathCell.Row
    udtInstanceParamsCurrent.RemoveAll
        
    ' For each parameter defined, add into a dictionary
    For Each param In Range(.Cells(Row, INSTANCES_COL_PARAMSSTART), .Cells(Row, .Cells(INSTANCES_ROW_HEADERS, 1).End(xlToRight).Column))
        paramName = .Cells(INSTANCES_ROW_HEADERS, param.Column)
                            
        udtInstanceParamsCurrent.Add paramName, param.Value
    Next
        
    ' TODO: Dictionary is being overwritten. need to set this to a new instance of the dictionary
    udtInstancesCurrent.Add deviceTagPath, udtInstanceParamsCurrent
Next

【问题讨论】：

标签： excel vba

【解决方案1】：

我解决了。我只需要将 udtInstanceParamsCurrent 设置为 for 循环内的新字典，而不是循环外。

Dim udtInstancesCurrent As Scripting.Dictionary
Dim udtInstanceParamsCurrent As Scripting.Dictionary
    
Set udtInstancesCurrent = New Scripting.Dictionary

'''' SAVE PARAMETER VALUES ''''
' For each udt instance tag path, add its param value into a dictionary to save its values
For Each udtTagPathCell In Range(.Cells(INSTANCES_ROW_HEADERS + 1, INSTANCES_COL_UDTTAGPATH), .Cells(INSTANCES_ROW_HEADERS, INSTANCES_COL_UDTTAGPATH).End(xlDown))
    Set udtInstanceParamsCurrent = New Scripting.Dictionary

    udtTagPath = udtTagPathCell.Value
    deviceName = .Cells(udtTagPathCell.Row, INSTANCES_COL_DEVICENAME)
    deviceParentPath = .Cells(udtTagPathCell.Row, INSTANCES_COL_DEVICEPARENTPATH)
    deviceTagPath = deviceParentPath & "/" & deviceName
    Row = udtTagPathCell.Row
    udtInstanceParamsCurrent.RemoveAll
        
    ' For each parameter defined, add into a dictionary
    For Each param In Range(.Cells(Row, INSTANCES_COL_PARAMSSTART), .Cells(Row, .Cells(INSTANCES_ROW_HEADERS, 1).End(xlToRight).Column))
        paramName = .Cells(INSTANCES_ROW_HEADERS, param.Column)
                            
        udtInstanceParamsCurrent.Add paramName, param.Value
    Next
        
    ' TODO: Dictionary is being overwritten. need to set this to a new instance of the dictionary
    udtInstancesCurrent.Add deviceTagPath, udtInstanceParamsCurrent
Next

【讨论】：