Unix shell：用字典替换

Question

我有一个包含一些数据的文件，像这样

2011-01-02 100100 1 
2011-01-02 100200 0
2011-01-02 100199 3
2011-01-02 100235 4

并在单独的文件中有一些“字典”

100100 Event1
100200 Event2
100199 Event3
100235 Event4

我知道

0 - warning
1 - error
2 - critical
etc...

我需要一些带有 sed/awk/grep 的脚本或其他可以帮助我接收此类数据的脚本

100100 Event1 Error
100200 Event2 Warning
100199 Event3 Critical
etc

将不胜感激如何以最佳方式做到这一点的想法，或工作示例

更新

有时我有这样的数据

2011-01-02 100100 1
2011-01-02 sometext 100200 0
2011-01-02 100199 3
2011-01-02 sometext 100235 4

其中 sometext = 任意 6 个字符（也许这是有用的信息）
在这种情况下，我需要整个数据：

2011-01-02 sometext EventNameFromDictionary Error

或者没有“sometext”

Answer 1

awk 'BEGIN {
 lvl[0] = "warning"
 lvl[1] = "error"
 lvl[2] = "critical"
 }
NR == FNR {
  evt[$1] = $2; next
  } 
{
  print $2, evt[$2], lvl[$3]
  }' dictionary infile

Answer 2

为新要求添加新答案，因为评论中的格式选项有限：

awk 'BEGIN {
 lvl[0] = "warning"
 lvl[1] = "error"
 lvl[2] = "critical"
 }
NR == FNR {
  evt[$1] = $2; next
  } 
{
  if (NF > 3) {
    idx = 3; $1 = $1 OFS $2
    }
  else idx = 2  
  print $1, $idx in evt ? \
    evt[$idx] : $idx, $++idx in lvl ? \
      lvl[$idx] : $idx
  }' dictionary infile

如果您使用的是 GNU awk，则无需转义三级运算符中的新行。

一些 awk 实现可能对这部分有问题：

$++idx in lvl ? lvl[$idx] : $idx

如果您使用其中之一， 将其更改为：

$(idx + 1) in lvl ? lvl[$(idx + 1)] : $(idx + 1)

好的，已添加 cmets：

awk 'BEGIN {
 lvl[0] = "warning"       # map the error levels
 lvl[1] = "error"                
 lvl[2] = "critical"      
 }                        
NR == FNR {               # while reading the first
                          # non-empty input file
  evt[$1] = $2          # build the associative array evt
  next                    # skip the rest of the program
                          # keyed by the value of the first column
                          # the second column represents the values
  }                       
{                         # now reading the rest of the input
  if (NF > 3) {           # if the number of columns is greater than 3
    idx = 3               # set idx to 3 (the key in evt)
    $1 = $1 OFS $2       # and merge $1 and $2
    }                     
  else idx = 2            # else set idx to 2
  print $1, \              # print the value of the first column
    $idx in evt ? \    # if the value of the second (or the third,
                  \       # depeneding on the value of idx), is an existing
                  \       # key in the evt array, print its value
    evt[$idx] : $idx, \ # otherwise print the actual column value
    $++idx in lvl ?   \   # the same here, but first increment the idx 
     lvl[$idx] : $idx       # because we're searching the lvl array now     
  }' dictionary infile

Answer 3

我希望 perl 也可以：

#!/usr/bin/perl
use strict;
use warnings;

open(DICT, 'dict.txt') or die;
my %dict = %{{ map { my ($id, $name) = split; $id => $name } (<DICT>) }};
close(DICT);

my %level = ( 0 => "warning", 
              1 => "error",
              2 => "critical" );

open(EVTS, 'events.txt') or die;

while (<EVTS>)
{
    my ($d, $i, $l) = split;
    $i = $dict{$i}  || $i;  # lookup
    $l = $level{$l} || $l;  # lookup 
    print "$d\t$i\t$l\n";
}

输出：

$ ./script.pl
2011-01-02      Event1  error
2011-01-02      Event2  warning
2011-01-02      Event3  3
2011-01-02      Event4  4