使用另一个包中的排序子例程

Question

我有一个像这样的脚本和一个包：

# file: sortscript.pl
use strict;
use warnings;
use SortPackage;

my @arrays = ([1,"array1"],[10,"array3"],[4,"array2"]);

print "Using sort outside package\n";
foreach (sort SortPackage::simplesort @arrays){
    print $_->[1],"\n";
}

print "\nUsing sort in same package\n";
SortPackage::sort_from_same_package(@arrays);

--

# file: SortPackage.pm
use strict;
use warnings;
package SortPackage;

sub simplesort{
    return ($a->[0] <=> $b->[0]);
}

sub sort_from_same_package{
    my @arrs = @_;
    foreach (sort simplesort @arrs){
        print $_->[1],"\n";
    } 
}
1;

运行脚本会产生输出：

$ perl sortscript.pl
Using sort outside package
Use of uninitialized value in numeric comparison (<=>) at SortPackage.pm line 15.
Use of uninitialized value in numeric comparison (<=>) at SortPackage.pm line 15.
Use of uninitialized value in numeric comparison (<=>) at SortPackage.pm line 15.
Use of uninitialized value in numeric comparison (<=>) at SortPackage.pm line 15.
Use of uninitialized value in numeric comparison (<=>) at SortPackage.pm line 15.
Use of uninitialized value in numeric comparison (<=>) at SortPackage.pm line 15.
array1
array3
array2

Using sort in same package
array1
array2
array3

为什么我无法正确使用子程序在另一个包中进行排序？

Answer 1

如前所述，$a 和 $b 是包全局变量，因此另一种解决方案是将调用站点的全局变量临时别名为包 SortPackage 中的全局变量：

{
    local (*a, *b) = (*SortPackage::a, *SortPackage::b);
    foreach (sort SortPackage::simplesort @arrays){
        print $_->[1],"\n";
    }
}

当然，这很丑陋。我只想让SortPackage 导出一个完整的排序例程，而不仅仅是一个比较器：

package SortPackage;
use strict;

sub _sort_by_first_element_comparator {
    return $a->[0] <=> $b->[0];
}

sub sort_by_first_element {
    return sort _sort_by_first_element_comparator @_;
}

Answer 2

$a 和 $b 是特殊的“包全局”变量。

要使用主作用域的$a 和$b，您的比较器函数必须引用$::a 或$main::a（同样适用于$b）。

但是，当从任何其他包，甚至在其自己的包中调用时，比较器函数将不起作用。

请参阅perlvars 帮助和perldoc 以了解sort 功能。解决方法也在后面的帮助文本中：

如果子程序的原型是"($$)"，则元素 比较是在@_ 中通过引用传递的，就像普通的一样 子程序。这比非原型子程序慢， 其中要比较的元素被传递到 子程序作为包全局变量$a 和$b（参见 下面的例子）。请注意，在后一种情况下，通常是 将 $a 和 $b 声明为词法会适得其反。

Answer 3

特殊变量$a 和$b 是包全局变量。您的子例程需要$SortPackage::a 和$SortPackage::b。当您从sortscript.pl 调用它时，变量$main::a 和$main::b 正在由sort 设置。

解决方案是使用原型子程序：

package SortPackage;

sub simplesort ($$) {
    return ($_[0]->[0] <=> $_[1]->[0]);
}

它有点慢（因为您传递的是实际参数，而不是读取预设的全局变量），但它允许您按名称使用来自其他包的子例程，就像您尝试的那样。