Delphi Tokyo - 函数：字符串到十六进制和十六进制到字符串

Question

下面的函数可以完美地将字符串转换为十六进制：

function String2Hex(const Buffer: AnsiString): string;
begin
  SetLength(Result, Length(Buffer) * 2);
  BinToHex(@Buffer[1], PWideChar(@Result[1]), Length(Buffer));
end;

ShowMessage(String2Hex('stackoverflow'));

这个结果：“737461636B6F766572666C6F77”

问题出在十六进制转字符串的功能上：

function Hex2String(const Buffer: AnsiString): string;
begin
  SetLength(Result, Length(Buffer) div 2);
  HexToBin(PWideChar(@Buffer[1]), @Result[1], Length(Buffer));
end;

ShowMessage(Hex2String('737461636B6F766572666C6F77'));

结果应该是“stackoverflow”，但没有任何反应。

有人可以帮我吗？

Answer 1

您的代码有几个问题：

1. 您将输入 AnsiString 错误地类型转换为 PWideChar，因此您调用了错误的 HexToBin() 重载。 PWideChar 应改为 PAnsiChar。

2. HexToBin() 的 BufSize 参数指定输出缓冲区期望接收的字节数，但您传递给它的是十六进制字符串中的字符数。

此外，由于String2Hex() 采用AnsiString 并返回UnicodeString，Hex2String() 应采用UnicodeString 并返回AnsiString 以匹配。

试试这个：

function String2Hex(const Buffer: AnsiString): string;
begin
  SetLength(Result, Length(Buffer) * 2);
  BinToHex(PAnsiChar(Buffer), PChar(Result), Length(Buffer));
end;

function Hex2String(const Buffer: string): AnsiString;
begin
  SetLength(Result, Length(Buffer) div 2);
  HexToBin(PChar(Buffer), PAnsiChar(Result), Length(Result));
end;

var
  hex: string;
  str: AnsiString;
begin
  hex := String2Hex('stackoverflow');
  ShowMessage(hex); // shows '737461636B6F766572666C6F77'
  str := Hex2String(hex);
  ShowMessage(str); // shows 'stackoverflow'
end;