如何在 Delphi 中关闭非模态表单

Question

这里已经讨论过了，但没有详细讨论。

我在尝试关闭非模态子表单时遇到了问题。我让它通知父母，但我收到抽象错误和其他异常。我究竟做错了什么？父母是否必须释放非模态表单，或者不再尝试通过该变量访问它？

主要形式：

NonModal := NonModalTForm.Create(Self);
NonModal.Callback := Callback;
NonModal.Show;

Procedure TForm.Callback; // called by non-modal form when closing 
begin
   FreeAndNil(NonModal);  // or should this just be NonModal := nil so I don't try to access a dangling pointer?
end;

在 NonModal.pas 中

procedure NonModalTForm.FormClose;
begin
  Callback; // calls parent
end;

Answer 1

您调用close 从FormClose 事件以外的某个地方关闭您的表单。在 FormClose 事件中，只需将 Action 设置为以下之一：

• caFree - 完全处理表单
• caMinimize - 最小化表单
• caHide - 隐藏表单
• caNone - 忽略关闭

例如：

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action := caFree;
end;

Answer 2

VCL 已经有一种机制可以在其他组件被释放时通知组件。你可以这样使用它；

type
  TfrmParent = class(TForm)
    btnShowChild: TButton;
    procedure btnShowChildClick(Sender: TObject);
  private
    FChild: TfrmChild;
  public
    procedure Notification(AComponent: TComponent; Operation: TOperation); override;
  end;


procedure TfrmParent.btnShowChildClick(Sender: TObject);
begin
  // Check status of child
  if FChild = nil then
  begin
    // Child does not exist, create it
    FChild:= TfrmChild.Create(Application);
    FChild.Show;

    // Ask Child to notify us when it is destroyed
    FChild.FreeNotification(Self);
  end
  else
  begin
    // Child already exists
    FChild.Show;
  end;
end;

procedure TfrmParent.Notification(AComponent: TComponent;
  Operation: TOperation);
begin
  inherited;

  if (AComponent = FChild) and (Operation = opRemove) then
  begin
    // FChild is about to be freed, so set reference to Child to nil
    FChild:= nil;
  end;
end;

创建子表单后，使用创建的表单的 FreeNotification 方法注册自己，以便在子表单被销毁时收到通知。

要对通知做出反应，请覆盖 Notification 方法。在那里，您可以找出哪个组件被销毁，并将其与记住的对子表单的引用进行比较。当您收到通知时，只需将子表单的引用设置为 nil。

在子 TfrmChild 本身中，除了 skamradt 所写的内容外，您无需执行任何其他操作：只需在 OnClose 事件中将参数 Actionb 设置为 caFree。

Answer 3

如果您想稍后显示窗口，请使用隐藏。

如果要关闭它，请使用 Close。 （关闭主窗口，关闭应用程序）。 Close 的具体操作取决于表单参数。

查看关闭的来源：

procedure TCustomForm.Close;
var
  CloseAction: TCloseAction;
begin
  if fsModal in FFormState then
    ModalResult := mrCancel
  else
    if CloseQuery then begin
      if FormStyle = fsMDIChild then
        if biMinimize in BorderIcons then
          CloseAction := caMinimize 
        else
          CloseAction := caNone
      else
        CloseAction := caHide;
      DoClose(CloseAction);
      if CloseAction <> caNone then
        if Application.MainForm = Self then 
          Application.Terminate
        else if CloseAction = caHide then 
          Hide
        else if CloseAction = caMinimize then 
          WindowState := wsMinimized
        else 
          Release;
    end;
end;

但要小心免费。 Windows 队列中可能有一些消息可能导致崩溃。最好使用 Release 来清理窗口。因为这会在释放它之前等待消息。

Answer 4

你正在做你不应该做的事。
在 NonModalForm 的 onClose 事件中，您调用一些直接释放它的代码，而它仍在事件处理程序执行中，因此您最终得到一个不再有效的 self 对象。
这就是为什么在表单上使用Release 而不是Free 的海报案例。

正如 Gamecat 指出的那样，只需调用 Close...
VCL 的美妙之处往往在于它就这么简单。

Answer 5

不要使用callback

只需调用FreeAndNil(Self); 即可释放为表单创建的所有内存资源。

请记住释放由您的实现代码创建的对象。 Delphi 对表单设计器创建的对象进行了很好的清理。