Delphi 应用程序 - 在 Windows 8 上阻止 Windows 键（开始）

Question

我正在编写一个 Delphi 应用程序。我的目标是用我的应用程序覆盖所有屏幕，以强制用户填写我的表格。应用程序将作为计划任务运行。

我的问题是，通常情况下，Windows 不允许应用程序阻止其他用户的操作。

在 Windows 7 中，我可以将我的应用程序作为 scr 文件（屏幕保护程序）运行，没有标题栏并设置 StayOnTop。在这种情况下，其他应用程序即使在“窗口键”（开始）上可见，也会留在我的应用程序后面，所以我的目标达到了。 不幸的是，在 Windows 8 中，这个解决方案不起作用，因为“窗口键”显示开始屏幕，当我可以运行任何东西并且这个“任何东西”保持在顶部时。

我用下面的代码尝试了一些技巧，但没有成功。

  h := FindWindowEx(FindWindow('Shell_TrayWnd', nil),0,'Button',nil);
  ShowWindow(h,0); 
  Windows.SetParent(h,0);

如何在整个 Windows 8 系统中阻止“窗口键”（开始按钮）动作？

Answer 1

我没有在 Windows 8 上测试它，但原则上可以使用键盘挂钩来丢弃按键。

类似于以下内容：

const   
    WH_KEYBOARD_LL   =   13;
    LLKHF_ALTDOWN    =   $00000020;
    LLKHF_INJECTED   =   $00000010;

type
    tagKBDLLHOOKSTRUCT   =   record
        vkCode:   DWORD;
        scanCode:   DWORD;
        flags:   DWORD;
        time:   DWORD;
        dwExtraInfo:   DWORD;
      end;
    KBDLLHOOKSTRUCT   =   tagKBDLLHOOKSTRUCT;
    LPKBDLLHOOKSTRUCT   =   ^KBDLLHOOKSTRUCT;
    PKBDLLHOOKSTRUCT   =   ^KBDLLHOOKSTRUCT;

var
    hhkLowLevelKybd:   HHOOK;

function LowLevelKeyBoardProc(nCode:   Integer;   awParam:   WPARAM;   alParam:   LPARAM):   LRESULT;   stdcall;
var
    fEatKeyStroke:   Boolean;
    p:   PKBDLLHOOKSTRUCT;
begin
    fEatKeystroke   :=   False;
    if active and(  nCode   =   HC_ACTION)   then
    begin
        case   awParam   of
            WM_KEYDOWN,
            WM_SYSKEYDOWN,
            WM_KEYUP,
            WM_SYSKEYUP:
                begin
                    p   :=   PKBDLLHOOKSTRUCT(alParam);
                    if DisableWinKeys then
                     begin
                      if p^.vkCode   =   VK_LWIN
                        then fEatKeystroke   :=   True;
                      if p^.vkCode   =   VK_RWIN
                        then fEatKeystroke   :=   True;
                     end;
                end;
        end;
    end;
    if   fEatKeyStroke   then
        Result := 1
    else
        Result := CallNextHookEx(hhkLowLevelKybd, nCode, awParam, alParam);
end;

procedure InstallHook;
begin
  if hhkLowLevelKybd <> 0 then exit;
  hhkLowLevelKybd := SetWindowsHookEx(WH_KEYBOARD_LL, @LowLevelKeyboardProc,   hInstance,   0);
end;

procedure UninstallHook;
begin
  if hhkLowLevelKybd = 0 then exit;
  UnhookWindowsHookEx(hhkLowLevelKybd);
  hhkLowLevelKybd := 0;
end;