不能在 Delphi XE8 中使用 MSSQL 时间戳作为参数

Question

我们正在将我们的一个项目从 Delphi XE 升级到 XE8。我们的审计代码使用 MSSQL（在本例中为 2012）数据库中的 TIMESTAMP 字段，并使用此作为 WHERE 子句中的参数从表中进行选择。

我们现在不再得到运行以下代码的任何结果：

procedure TForm2.Button1Click(Sender: TObject);
begin
  ADODataset1.CommandText := 'SELECT * FROM CURRENCYAUDIT';
  ADODataset2.CommandText := 'SELECT * FROM CURRENCYAUDIT WHERE Audit_Timestamp = :Timestamp';
  ADODataset2.Parameters.Refresh;

  ADODataset1.Open;
  if ADODataset1.FieldByName('audit_timestamp').IsNull or ADODataset1.IsEmpty then
  begin
    showmessage('nothing to compare');
  end;

  ADODataset2.Parameters[0].Value := ADODataset1.FieldByName('audit_timestamp').Value;
  ADODataset2.Open;
  caption := inttostr(ADODataset2.RecordCount);
end;

CurrencyAudit 是包含非空时间戳 audit_timestamp 字段的任何旧 MSSQL 表。

表单的标题为 0，不显示任何消息。

知道如何让它工作吗？尝试过 AsString（无意义字符串，0 个结果）、AsSQLTimestamp（参数不接受）和 AsBytes（0 个返回）。不幸的是，.Value 的返回仅评估为“字节的变体数组”，这对可视化/查看它是什么没有帮助。

编辑：将其作为 .AsBytes 运行并在调试器中查看，我可以看到 XE 版本返回 0,0,0,0,0,8,177,22 而 XE8 返回 17,32,0,0 ,0,0,0,0。检查（真实）数据库的其他字段显示记录是相同的。看起来像是从数据库中读取 TIMESTAMP 的错误

Answer 1

我正在使用两个 AdoQueries。以下在 D7 中对我来说很好，在 AdoQuery2 中正确返回 1 行，但在 XE8 中返回 0 条记录，因此显然与您遇到的 XE8 问题相同。

var
  S : String;
  V : Variant;
begin
  AdoQuery1.Open;
  S := AdoQuery1.FieldByName('ATimeStamp').AsString;
  V := AdoQuery1.FieldByName('ATimeStamp').AsVariant;
  Caption := S;
  AdoQuery2.Parameters.ParamByName('ATimeStamp').Value := V;
  AdoQuery2.Open;

只是为了测试，我在同一个服务器表上运行我的 AdoQuery1 和 AdoQuery2。

更新：我有一种与您的答案类似的方法，它可以避免需要您的 Int64ToByteArray，但代价是一些稍微混乱（且效率较低）的 Sql，这可能不合你的口味。

在我的源 AdoQuery 中，我有这个 Sql

select *, convert(int, atimestamp) as inttimestamp from timestamps

在目的地

select *  from timestamps where convert(int, atimestamp) = :inttimestamp

这当然避免了在第二个 AdoQuery 上需要 varBytes 参数，因为可以获取时间戳列值的整数版本并将其分配给 inttimestamp 参数。

顺便说一句，在你原来的q中

  if ADODataset1.FieldByName('audit_timestamp').IsNull or ADODataset1.IsEmpty then

这两个表达式最好反过来写。除非 ADODataset1 具有持久字段，否则如果打开时不包含任何记录，则引用 audit_timestamp 应该会引发“未找到字段”异常。

Answer 2

EMBT 似乎破坏了 TIMESTAMP 到字节数组的转换。 XE 版本的 bytearray 是正确的，可以手动将数据拉下为 int64，然后手动构建 bytearray（是否有开箱即用的功能？）并将其用作 XE8 中的参数。

我不知道这是否是其他二进制数据类型的类似问题。希望不会！

工作代码：

procedure TForm2.Button1Click(Sender: TObject);
var
  TestArray: TArray<Byte>;
  j: integer;
  function Int64ToByteArray(const inInt: uint64): TArray<Byte>;
  var
    i: integer;
    lInt: int64;
  begin
    SetLength(result, 8);
    lInt := inint;
    for i := low(result) to high(result) do
    begin
      result[high(result)-i] := lInt and $FF;
      lInt := lInt shr 8;
    end;

  end;

begin
  ADODataset1.CommandText := 'SELECT  *, cast(audit_timestamp as bigint) tmp FROM CURRENCYAUDIT';
  ADODataset2.CommandText := 'SELECT * FROM CURRENCYAUDIT WHERE Audit_Timestamp = :Timestamp';
  ADODataset2.Parameters.Refresh;

  ADODataset1.Open;
  if ADODataset1.FieldByName('audit_timestamp').IsNull or ADODataset1.IsEmpty then
  begin
    showmessage('nothing to compare');
  end;

  ADODataset2.Parameters[0].Value := Int64ToByteArray(ADODataset1.FieldByName('tmp').asInteger);
  ADODataset2.Open;
  caption := inttostr(ADODataset2.RecordCount);
end;

我还检查了我的整个（真实）表并确保所有其他字段匹配以确保它不是一次性的！

我会向 EMBT 提出一张罚单，让他们坐下来忽略 5 年 ;-)

https://quality.embarcadero.com/browse/RSP-11644