Delphi：泛型和 TObjectList

Question

我创建了一个类

TMyClass = class(TObject)
private
  FList1: TObjectList<List1>;
  FList2: TObjectList<List2>;
public
end;

现在，我想要一个方法FillArray(Content);，最好应该实现一次，即没有重载。我相信使用泛型可以做到这一点，但我对这些野兽太缺乏经验，无法实际实现它。有人有线索吗？提前致谢！

Answer 1

我相信以下内容仅适用于 Delphi 2010。由于它取决于系统单元中 TArray 的声明，因此如下所示：

  TArray<T> = array of T;

这是我开发的用于帮助 TArray 到列表转换的单元

unit ListTools;

interface                
uses Generics.Collections;
type
 TListTools = class(TObject)
 public
    // Convert TList<T> to TArray<T>
    class function ToArray<T>(AList: TList<T>): TArray<T>;
    // Append Array elements in AValues to AList
    class procedure AppendList<T>(AList : TList<T>;AValues : TArray<T>);
    // Clear List and Append Values to aList
    class procedure ToList<T>(AList : TList<T>;AValues : TArray<T>);
 end;

implementation

{ TListTools }

class procedure TListTools.AppendList<T>(AList: TList<T>; AValues: TArray<T>);
var
  Element : T;
begin
  for Element in AValues do
  begin
     AList.Add(Element);
  end;
end;

class function TListTools.ToArray<T>(AList: TList<T>): TArray<T>;
// taken from rtti.pas
var
  i : Integer;
begin
  SetLength(Result, AList.Count);
  for i := 0 to AList.Count - 1 do
    Result[i] := AList[i];
end;

class procedure TListTools.ToList<T>(AList: TList<T>; AValues: TArray<T>);
begin
   AList.Clear;
   AppendList<T>(AList,AValues);
end;

end.

由于 TList 是 TObjectList 的父类，它应该可以与 TObjectList 一起使用，尽管我没有尝试过。