导航 Access 数据库行的下一步按钮

Question

我有代码，当你按下下一个按钮时，它会滚动数据库行，但我希望它在到达最后一行时显示错误，当你点击下一个时，它不能再进一步，因为它是最后一行，但似乎一直循环在我身上，当我按下下一个按钮时永远不会结束？有任何想法吗？ 我有一个变量，它在表单加载时是 = 到 -1。

代码：

Private Sub searchclickbinds()
    If con.State = ConnectionState.Closed Then con.Open()
    'create data adapters
    sql = "Select * from tbl"
    da = New OleDbDataAdapter(sql, con)
    da.Fill(ds, "tbl")
    RecCnt = ds.Tables("tbl").Rows.Count   'how many records in ds

    TxtCI.Text = ds.Tables("tbl").Rows(inc).Item(0)

    Dim word
    word = ds.Tables("tbl").Rows(inc).Item(15)

    con.Close()
End Sub

来电者：

Private Sub BtnNext_Click(sender As Object, e As EventArgs) Handles BtnNext.Click
    If inc <> RecCnt - 1 Then
        inc = inc + 1
        nclick()
    End If

End Sub

表单加载：

Private Sub main_Load(sender As Object, e As EventArgs) Handles Me.Load
    inc = -1
End Sub

Answer 1

这就是 jmcilhinney 先生在 cmets 中所描述的内容（以及其他一些注释和观察）：

' form level vars we need:
Private bsSample As BindingSource
Private dtSample As DataTable
Private ACEConnStr As String = "Provider=Microsoft.ACE.OLEDB.12.0...YOUR CONN STRING..."

然后加载数据：

Dim sql = "SELECT Id, Name, Descr, ValueA,  Fish, Bird, Color, Active FROM Sample"

Using dbcon As New OleDbConnection(ACEConnStr)
    Using cmd As New OleDbCommand(sql, dbcon)

        dbcon.Open()

        dtSample = New DataTable
        dtSample.Load(cmd.ExecuteReader)

    End Using
End Using

1. 如果您只使用一个表，则不需要 DataSet 来存储该表。
2. 如图所示，您不需要 DataAdapter 来填充表格，尤其是在您仅在本地使用它们的情况下。您可能需要一级表单（如 DT 或 BindingSource）来轻松更改表格：myDa.Update(dtSample)¹
3. 如果您计划通过DataTable 添加数据或在DataGridView 中显示数据，它有助于指定SQL 中的列顺序而不是SELECT *
4. Access 不太正确，但您应该打开、使用、然后处置 Connection 对象。缺少一个con.Close 语句可能会导致各种错误。使用块关闭并在最后处理东西以释放资源。

另请注意，如果您有一个 DataTable 的所有客户，您可以使用 that 在根据上一个问题删除之前查看#30 是否存在。现在绑定：

 ' initialize BS from DT
bsSample = New BindingSource(dtSample, Nothing)

tbName.DataBindings.Add("Text", bsSample, "Name")
tbDescr.DataBindings.Add("Text", bsSample, "Descr")
chkActive.DataBindings.Add("Checked", bsSample, "Active")

第一行初始化BindingSource。最后一部分设置“映射”。例如，tbName 的 Text 属性设置为显示来自 bsSample 源的“名称”数据库数据。 CheckBox 将 Active 数据（布尔）显示为 Checked 属性。

BindingSource 具有您可以使用的各种方法和属性。您的下一步按钮：

Private Sub btnNext_Click(sender As Object, e As EventArgs) Handles btnNext.Click
    bsSample.MoveNext()

    btnNext.Enabled = (bsSample.Count - 1 > bsSample.Position)
    ' To Do: add similar code for btnPrev
End Sub

请注意，用户对控件的更改将应用​​于DataTable，但不会应用于数据库。如果您不希望用户能够以这种方式进行编辑，一个简单的方法是使用DataView：

Dim dv = New DataView(dtSample)
dv.AllowEdit = False
bsSample = New BindingSource(dv, Nothing)

您还可以根据每个字段禁用对源的更新：

tbName.DataBindings.Add("Text", bsSample, "Name", False, DataSourceUpdateMode.Never)

也许最简单的是：

dgv.ReadOnly = True
dgv.DataSource = dtSample

不要将 DataGridView 拖放到表单上，并将DataSource 设置为您的DataTable，看看它是多么容易使用。太多人不必要地害怕它。

¹ 这就是通过 DataAdapter 一次性添加、删除和更新 DataTable 中任意数量的行的全部内容。将它们设置为执行此操作需要几行代码，尽管很少。