从根本上说，你不能做你想做的事：
ValueMember= "Fixed"
DisplayMember= "Specific and unique number"
Value- 和DisplayMember 不是用于指定文字值，而是用于在其他东西（如类）中指示属性名称。
不使用DataSource（标题）与不使用类（问题文本）不同。创建类还有其他方法：
现有的 NET 类型
您可以使用现有的 NET KeyValuePair 类将值与名称链接：
cbox.Items.Add(New KeyValuePair(Of String, String)("Specific",
"Specific and unique number"))
cbox.Items.Add(New KeyValuePair(Of String, String)("Multiple",
"Multiple and different numbers"))
cbox.Items.Add(New KeyValuePair(Of String, String)("Repeated",
"One number repeated x times"))
cbox.ValueMember = "Key"
cbox.DisplayMember = "Value"
没有 DataSource - 数据在 items 集合中。如另一个答案中所述，还有Tuple
匿名类型
使用一个字符串作为另一个字符串的键是很奇怪的。通常在代码中，您会想要一些不太容易因拼写错误而出错的东西。在某处键入“Fized”会破坏您的代码。 Enum 更有意义：
Private Enum ValueStyle
Specific = 0
Multiple = 1
Repeated = 2
End Enum
现在，您可以创建一个 List 链接用户的描述和 Enum 常量：
' fuller text descr of the enum for the user
Dim descr As String() = {"Specific and unique number",
"Multiple and different numbers",
"One number repeated x times"}
' get enum values into an array of ValueStyle
Dim values = [Enum].GetValues(GetType(ValueStyle)).Cast(Of ValueStyle).ToArray
' create a List of anon objects from the descr() and values()
Dim lst = values.Select( Function (q) New With
{.Value = q, .Name = descr (q)}
).ToList()
cboPicker.ValueMember = "Value"
cboPicker.DisplayMember = "Name"
cboPicker.DataSource = lst
这将创建一个 匿名类型 - 一个没有类的对象 - 其名称和值属性映射到枚举和描述数组。如果 Enum 值不是连续的（例如 {8, 65, 99}），则必须以不同的方式构建列表。
这会创建一个 匿名类型 对象的临时集合，并将其分配为 DataSource。您将无法在其他方法中访问Name 和Value 属性，因为无法将匿名类型传递给其他方法。但是用户将看到所需的文本，NET/VB 将提供值作为该枚举作为SelectedValue。使用SelectedValue changed 事件：
' name user sees == cboPicker.Text
' value == cboPicker.SelectedValue boxed as Object
Dim userChoice As ValueStyle = CType(cboPicker.SelectedValue, ValueStyle)
If userChoice = ValueStyle.Specific Then
'...
ElseIf userChoice = ValueStyle.Repeated Then
'...
End If
请注意，代码不是将“Fixed”作为字符串进行测试，而是使用枚举，但仍然具有可读性。
MSDN：Anonymous Types (Visual Basic)
那些符合不需要新课程的标准，但请考虑：
Friend Class NameValuePair
Public Property Name As String
Public Property Value As Int32
Public Sub New(n As String, v As Int32)
Name = n
Value = v
End Sub
Public Overrides Function ToString() As String
Return Name
End Function
End Class
这个类非常简单，几乎可以无限地重复使用任何Name 与任何Value。它可以在任意数量的项目中与任意数量的基于列表的控件一起使用。创建和使用它们的列表的代码比使用其他方法更简单。