如何手动修改 worksheet_change 事件中正在编辑的单元格？

Question

我遇到了一些麻烦，需要一些帮助。我需要创建代码来根据单元格的值更改命名范围的值。有 4 个选项：A、B、C 和无。如果选择 A、B 或 C，我需要在命名范围中输入预设值，将范围的颜色更改为灰色，并锁定单元格。如果选择无，命名范围将变为黄色，用户将在命名范围中输入自己的值。以下是我正在尝试的代码：

Private Sub Worksheet_Change(ByVal Target As Range)

Dim ws As Worksheet

Application.EnableEvents = False
Application.ScreenUpdating = False

Set ws = ThisWorkbook.Sheets("Sheet1")

ws.Unprotect Password:="MyPass"

If ws.Range("L14") = "A" Then
    ws.Range("NamedRange").Rows(1) = "Option 1"
    
    ws.Range("NamedRange").Interior.ColorIndex = 15
    ws.Range("NamedRange").Locked = True
    
ElseIf ws.Range("L14") = "B" Then
    ws.Range("NamedRange").Rows(1) = "Option 2"
    
    ws.Range("NamedRange").Interior.ColorIndex = 15
    ws.Range("NamedRange").Locked = True

ElseIf ws.Range("L14") = "C" Then
    ws.Range("NamedRange").Rows(1) = "Option 3"

    ws.Range("NamedRange").Interior.ColorIndex = 15
    ws.Range("NamedRange").Locked = True
    
Else 'user input own entries
    ws.Range("NamedRange").ClearContents
    ws.Range("NamedRange").Interior.ColorIndex = 6
    ws.Range("NamedRange").Locked = False
End If

ws.Protect Password:="MyPass"

Application.EnableEvents = True
Application.ScreenUpdating = True

End Sub

我遇到的问题是选择“无”。单元格变为黄色并解锁，但因为我正在使用工作表更改事件，所以我尝试输入的任何值都会自动清除。当使用工作表更改事件选择“无”时，是否有任何方法允许用户更改命名范围？

Answer 1

但您没有在代码中使用Target 单元格...。您希望工作表中的所有单元格更改触发事件吗？最好用 cote 行开始事件：If Target.Address <> "$L$14" Then Exit Sub，作为一个工作表事件，不需要使用ws 并对其进行限定。它指的是活动单元格，简单地使用Range("L14")就足够了。然后，最后一个Else 并没有像您可能想要的那样引用“L14”中的更改...

请测试最后一种方式：

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)

 If Target.Address <> "$L$14" Then Exit Sub
 Application.EnableEvents = False

 ActiveSheet.Unprotect Password:="MyPass"
 Select Case Target.Value
    Case "A"
        Range("NamedRange").rows(1) = "Option 1"
        
        Range("NamedRange").Interior.ColorIndex = 15
        Range("NamedRange").Locked = True
    Case "B"
        Range("NamedRange").rows(1) = "Option 2"
    
        Range("NamedRange").Interior.ColorIndex = 15
        Range("NamedRange").Locked = True
    Case "C"
        Range("NamedRange").rows(1) = "Option 3"

        Range("NamedRange").Interior.ColorIndex = 15
        Range("NamedRange").Locked = True
    Case Else
        Range("NamedRange").ClearContents
        Range("NamedRange").Interior.ColorIndex = 6
        Range("NamedRange").Locked = False
 End Select

 ActiveSheet.Protect Password:="MyPass"
 Application.EnableEvents = True
End Sub

代码未经测试，但我认为它应该可以工作。请对其进行测试并发送一些反馈。