无法获取 .net 类中声明的方法列表

Question

阅读了大量关于使用反射获取给定类中的方法列表的帖子，但我仍然无法获得该列表，需要寻求帮助。这是我当前的代码：

Function GetClassMethods(ByVal theType As Type) As List(Of String)
    Dim methodNames As New List(Of String)
    For Each method In theType.GetMethods()
        methodNames.Add(method.Name)
    Next
    Return methodNames
End Function

我这样称呼这个方法：

GetClassMethods(GetType(HomeController))

return 有 43 个方法，但我只想要我在类中写的方法。下图显示了返回内容的开头。我声明的方法在此列表中，但位于位置 31-37。实际上有 9 个声明的方法，但是这个列表没有显示 Private 方法。

当我查看theType 时，我看到了我想要的属性。它是DeclaredMethods，它显示了每个声明的方法，公共的和私有的。

但是，我无法使用这样的语句访问此属性。

Dim methodList = theType.DeclaredMethods

返回的错误是DelaredMethods不是Type的成员。所以，我的问题是多方面的：

1) 最重要的是，我需要什么代码来检索类中每个声明的方法，并且只检索我声明的方法？

2) 为什么我无法访问提供 DeclaredMethods() 列表的属性？

Answer 1

试试这个：

Function GetClassMethods(ByVal theType As Type) As List(Of String)
    Dim flags = Reflection.BindingFlags.Instance Or Reflection.BindingFlags.Public Or Reflection.BindingFlags.DeclaredOnly
    Dim result = theType.GetMethods(flags).
          Where(Function(m)  Not m.IsSpecialName).
          Select(Function(m) m.Name)
    Return result.ToList()
End Function

或者为了一些泛型的乐趣：

Function GetClassMethods(Of T)() As List(Of String)
    Dim flags = Reflection.BindingFlags.Instance Or Reflection.BindingFlags.Public Or Reflection.BindingFlags.DeclaredOnly
    Dim result = GetType(T).GetMethods(flags).
          Where(Function(m)  Not m.IsSpecialName).
          Select(Function(m) m.Name)
    Return result.ToList()
End Function

IsSpecialName 过滤器排除具有编译器生成名称的方法，例如编译器用于实现属性的特殊方法。如果您还需要包括 NonPublic 成员，您还可以更多地使用标志。

---

最后，每当你有一个以Return something.ToList() 结尾的方法（或者可以以它结尾，正如我的改编在这里展示的那样），更改方法以返回IEnumerable(Of T) 几乎总是更好 strong>，如果确实需要，让调用代码调用ToList()。所以我上面的第一个例子真的更好：

Function GetClassMethods(ByVal theType As Type) As IEnumerable(Of String)
    Dim flags = Reflection.BindingFlags.Instance Or Reflection.BindingFlags.Public Or Reflection.BindingFlags.DeclaredOnly
    Return theType.GetMethods(flags).
          Where(Function(m)  Not m.IsSpecialName).
          Select(Function(m) m.Name)
End Function

嘿，那可能是单线。那么对于那些你确实需要列表的情况，你可以这样做：

Dim methodNames As List(Of String) = GetClassMethods(HomeController).ToList()

你会开始发现在很多情况下你根本不需要使用ToList()；通用的IEnumerable 已经足够好了。当然，只要将结果与For Each 循环一起使用，任何地方都是如此。现在突然之间，您的程序中的内存使用量大大减少了。