用户控件控制包含表单

Question

我正在使用 vb.net winforms 创建一个包含用户控件的应用程序，我也在创作用户控件。

用户控件名为activate1

包含用户控件（和其他内容）的表单被命名为 form1

目前我正在尝试在激活 1 上的蒙版文本框完成时启用 form1 上的按钮

我尝试这样做：

Private Sub MaskedTextBox1_TextChanged(sender As Object, e As EventArgs) Handles MaskedTextBox1.TextChanged
    If MaskedTextBox1.Text.Count = 34 Then
        Form1.SimpleButton1.Enabled = True
    Else
        Form1.SimpleButton1.Enabled = False
    End If
End Sub

但是我在运行应用程序时收到错误“表单在从默认实例构造期间引用自身，这导致了无限递归”所以我尝试了

Private Sub MaskedTextBox1_TextChanged(sender As Object, e As EventArgs) Handles MaskedTextBox1.TextChanged
    If MaskedTextBox1.Text.Count = 34 Then
        me.SimpleButton1.Enabled = True
    Else
        me.SimpleButton1.Enabled = False
    End If
End Sub

但是这个标志并且不允许编译，因为我指的是用户控件中不存在的按钮

我怎样才能做到这一点

Answer 1

第一个错误的原因是您使用类型名称来引用 Form1，您需要父表单的具体实例。您可以通过访问ParentForm-property 来访问父表单：

Private Sub MaskedTextBox1_TextChanged(sender As Object, e As EventArgs) Handles MaskedTextBox1.TextChanged
    Dim form = TryCast(ParentForm, Form1)
    If form IsNot Nothing Then
        If MaskedTextBox1.Text.Count = 34 Then
            form.SimpleButton1.Enabled = True
        Else
            form.SimpleButton1.Enabled = False
        End If
    End If
End Sub

请注意，这种方法将您的 Form 和您的 UserControl 紧密结合在一起。虽然它会起作用，但它会降低 UserControl 的可重用性（事实上，您只能在 Form1 上使用它，而不能在其他窗体上使用它）。尽管您可以改进这一点，例如通过创建一个界面，但 UserControl 将始终以一种或另一种方式绑定到支持此按钮的表单。
一种更可重用的方法是在您的 UserControl 中引发一个事件并在父表单中处理它，例如：

Public Class ActivationInfoEventArgs
    Inherits EventArgs

    Public Property Completed As Boolean
End Class

Public Event ActivationInfoChanged As EventHandler(Of ActivationInfoEventArgs)

Private Sub MaskedTextBox1_TextChanged(sender As Object, e As EventArgs) Handles MaskedTextBox1.TextChanged
    Dim completed As Boolean
    If MaskedTextBox1.Text.Count = 34 Then
        completed = True
    Else
        completed = False
    End If
    RaiseEvent ActivationInfoChanged(Me, New ActivationInfoEventArgs() With { .Completed = completed })
End Sub

您为 Form1 中的事件添加一个处理程序并（取消）激活此处理程序中的按钮。这样，您就可以在更多种类的表单上使用 UserControl。