有没有办法引用变量和控件来使用控件文本字段更新所述变量？

Question

基本上，我在 LostFocus 上有几百个控件需要更新位于类中的不同变量。

Private Sub txtFirstName_LostFocus(sender As Object, e As System.EventArgs) Handles txtFirstNameMain.LostFocus
    Interview.FIRSTNAME = txtFirstNameMain.Text
End Sub
Private Sub txtLastName_LostFocus(sender As Object, e As System.EventArgs) Handles txtLastNameMain.LostFocus
    Interview.LASTNAME = txtLastNameMain.Text
End Sub

有没有办法创建一个可以处理这个问题的 Sub？也许我可以将目标变量放在控件的标签上？但是，如果没有大量代码工作，我将如何引用所述变量呢？

Private Sub Lost_Focus_UpdateClass(sender As TextBox, e As System.EventArgs) Handles txtFirstNameMain.LostFocus, txtLastNameMain.LostFocus
    Select Case sender.Tag
        Case "FIRSTNAME"
            Interview.FIRSTNAME = sender.Text
        Case "LASTNAME"
            Interview.LASTNAME = sender.Text
    End Select
End Sub

这只是感觉它所做的事情需要太多。有没有更好的方法来处理这个问题？

我正在使用 WinForms。

编辑：TnTinMn - 工作。必须对可空字段进行更改。

    Me.tbFirstName.DataBindings.Add("Text", dataStore, "FirstName", True, DataSourceUpdateMode.OnValidation, String.Empty)
    Me.tbLastName.DataBindings.Add("Text", dataStore, "LastName", True, DataSourceUpdateMode.OnValidation, String.Empty)

Answer 1

根据您描述的目标，将控件绑定到类属性的数据应该可以工作。

Public Class Form1
    Private dataStore As Example
    Protected Overrides Sub OnLoad(e As EventArgs)
        MyBase.OnLoad(e)
        Me.SetupDataStore()
    End Sub

    Private Sub SetupDataStore()
        Me.dataStore = New Example
        Me.tbFirstName.DataBindings.Add("Text", dataStore, "FirstName", True, DataSourceUpdateMode.OnValidation)
        Me.tbLastName.DataBindings.Add("Text", dataStore, "LastName", True, DataSourceUpdateMode.OnValidation)
    End Sub

End Class

Friend Class Example
    Public Property FirstName As String
    Public Property LastName As String
End Class