通过 Interfaces 处理 Null 对象引用

Question

我有一个对象Foo，但我并不拥有它（第三方程序集），我想通过接口IFoo。

在通过接口传递所有内容之前，我有一个Function TryGet(Name As String) as Foo。当找不到名称时，此函数将返回 Nothing。

现在将所有内容重构为接口，我有Function TryGet(Name As String) as IFoo。

IFoo的实现是：

Public Class SuperFoo
    Implements IFoo

    Private ThisFoo As Foo

    Private Sub New()
    End Sub

    Public Sub New(MyFoo As Foo)
        Me.ThisFoo = MyFoo
    End Sub

    Public Property Value As String Implements IFoo.Value
        Get
            Return Me.ThisFoo.Value
        End Get
        Set(value As String)
            Me.ThisFoo.Value = value
        End Set
    End Property

End Class

Class AnotherClass

    Function TryGet(Name as String) as IFoo
        Dim MyFoo as Foo = InitialTryGetFunction(Name)
        Return New SuperFoo(MyFoo)
    End Function

End Class

为了保持我的原始代码逻辑，我希望能够在InitialTryGetFunction 返回空引用时将对SuperFoo 对象的引用设为空。

显然我可以在If Return New SuperFoo(MyFoo) 语句中添加一些代码，但我想知道这是否可以通过SuperFoo 构造函数完成？

另外，我是否正确地切换到接口（主要用于单元测试）？

Answer 1

您可以使用SuperFoo 中的扩展运算符来完成此操作，该运算符将Foo 转换为SuperFoo。由于运算符是Shared，如果给定的Foo 是Nothing，则可以返回Nothing，否则返回一个新的SuperFoo。

Public Shared Widening Operator CType(ByVal x As Foo) As SuperFoo
    Return If(x Is Nothing, Nothing, New SuperFoo(x))
End Operator

VB.Net 解决的很好，我想你甚至可以像这样直接退货（未经测试，无保修）：

    Function TryGet(Name as String) as IFoo
        Return InitialTryGetFunction(Name) 'Converts into SuperFoo which is cast into IFoo
    End Function

（如果不起作用，请使用）

    Function TryGet(Name as String) as IFoo
        Dim myResult As SuperFoo = InitialTryGetFunction(Name)
        Return myResult
    End Function

Answer 2

根据 Christoph 的回答，我遇到了一个后续问题，即 Foo 实际上是一个接口本身（通过 COM 互操作公开）。

对于面临同样问题的任何人，这是我的处理方法：

Public Class SuperFoo
    Implements IFoo

    Private ThisFoo As Foo

    Private Sub New()
    End Sub

    Public Sub New(MyFoo As Foo)
        Me.ThisFoo = MyFoo
    End Sub

    Public Shared Function GetNew(obj as Foo) As SuperFoo
        Return If(obj Is Nothing, Nothing, New SuperFoo(obj))
    End Function

    Public Property Value As String Implements IFoo.Value
        Get
            Return Me.ThisFoo.Value
        End Get
        Set(value As String)
            Me.ThisFoo.Value = value
        End Set
    End Property

End Class

Class AnotherClass

    Function TryGet(Name as String) as IFoo
        Dim MyFoo as Foo = InitialTryGetFunction(Name)
        Return SuperFoo.GetNew(MyFoo)
    End Function

End Class

我给 Christoph 提供了公认的答案，因为他提供了一般情况的答案。