为什么没有为子类生成接口表？

Question

我有以下问题：

• 实现某个接口的基类
• 从基类派生并覆盖接口方法的另一个类

对于子类根本不生成接口表。

type
  ITest = interface
    ['{69068A88-6712-40E0-B1E3-DA265F7428EA}']
    procedure Test;
  end;

  TBase = class(TInterfacedObject, ITest)
  protected
    procedure Test; virtual;
  public
    constructor Create;
  end;

  TChild = class(TBase)
  protected
    procedure Test; override;
  end;

constructor TBase.Create;
begin
  Assert(GetInterfaceTable <> nil);
end;

所以当使用以下构造时：

var
  X: ITest;
begin
  X := TChild.Create;
end;

我得到断言失败。

所以我知道我需要在类声明中重新声明接口来解决这个问题。但这是语言特性还是编译器的老问题？

因为在编译时编译器知道 TChild 正在实现 ITest 接口。但是一旦我们进入运行时，我确实需要从基础重复重新声明接口！我们为什么要这样做？对我来说，它看起来很糟糕。

Answer 1

如文档所述，GetInterfaceTable 返回类的接口条目列表。在您的情况下，TChild 本身没有实现任何接口。

返回一个指向包含所有接口的结构的指针 由给定的类实现。

GetInterfaceTable 返回类的接口条目。这 list 只包含这个类实现的接口，而不是它的 祖先。要查找祖先列表，请迭代调用 ClassParent 和 然后在它返回的值上调用 GetInterfaceTable。查找条目 对于特定接口，请改用 GetInterfaceEntry 方法。

GetInterfaceTable 是类函数，就像ClassName 是类函数一样。它取决于实例类而不是您从代码的哪一部分调用它：

如果你运行下面的代码，它会给你不同的ClassName，不管你在TBase构造函数中调用代码。

constructor TBase.Create;
begin
  writeln(ClassName);
end;

var
  x : ITest;

   X := TBase.Create; // outputs TBase
   X := TChild.Create; // outputs TChild

Answer 2

这是设计的。

AFAIR GetInterfaceTable 是一个非常底层的方法，它只在给定的类级别上工作。你不应该在你的代码中使用这个方法，除非你弄乱了低级别的 RTTI 信息......但在所有情况下，你最好不要使用它。

这里是如何实现的：

class function TObject.GetInterfaceTable: PInterfaceTable;
begin
  Result := PPointer(PByte(Self) + vmtIntfTable)^;
end;

因此，您还必须使用递归调用或循环来检查父类的类型。

例如，下面是它在 System.pas 中的使用示例：

class function TObject.InitInstance(Instance: Pointer): TObject;
var
  IntfTable: PInterfaceTable;
  ClassPtr: TClass;
  I: Integer;
begin
  FillChar(Instance^, InstanceSize, 0);
  PPointer(Instance)^ := Pointer(Self);
  ClassPtr := Self;
  while ClassPtr <> nil do
  begin
    IntfTable := ClassPtr.GetInterfaceTable;
    if IntfTable <> nil then
      for I := 0 to IntfTable.EntryCount-1 do
        with IntfTable.Entries[I] do
        begin
          if VTable <> nil then
            PPointer(@PByte(Instance)[IOffset])^ := VTable;
        end;
    ClassPtr := ClassPtr.ClassParent;
  end;
  Result := Instance;
end;

相当低级的东西，不是吗？

要实现 IoC 模式，您宁愿使用 TObject.GetInterfaceEntry()，它可以满足您的期望。