通过类变量构造对象总是需要父类有构造函数吗？

Question

我知道这是一个令人费解的问题，我相信有人可以将其简化为基本问题。

考虑以下代码：

TTestClass = class
public
end;

TTestClassDescendant = class(TTestClass)
public
  constructor Create;
end;


implementation

procedure TForm1.Button1Click(Sender: TObject);
var tc: TTestClass;
begin
  tc := TTestClassDescendant.Create;
  tc.Free;
end;

{ TTestClassDescendant }

constructor TTestClassDescendant.Create;
begin
  ShowMessage('Create executed')  // this gets executed
end;

Create 过程被正确执行。

现在考虑以下代码：

TTestClass = class
public
end;

TTestClassDescendant = class(TTestClass)
public
  constructor Create;
end;

TTestClassClass = class of TTestClass;

implementation

procedure TForm1.Button1Click(Sender: TObject);
var tc: TTestClass;
    tcc: TTestClassClass;
begin
  tcc := TTestClassDescendant;
  tc := tcc.Create;
  tc.Free
end;

{ TTestClassDescendant }

constructor TTestClassDescendant.Create;
begin
  ShowMessage('Create executed')  // this does NOT get executed
end;

后代类的 Create 过程不再执行。

但是，如果我在父类中引入构造函数并在后代类中覆盖它，它确实会被执行：

TTestClass = class
public
  constructor Create; virtual;
end;

TTestClassDescendant = class(TTestClass)
public
  constructor Create; override;
end;

如果我忽略了显而易见的事情，请原谅我，但不应该在通过类变量进行构造时执行第二个代码块中的构造函数代码，就像通过类标识符本身调用它时一样?

Answer 1

如果我忽略了显而易见的事情，请原谅我，但不应该 当第二个代码块中的构造函数代码被执行时 构造是通过一个类变量发生的，就像它是 通过类标识符本身调用？

不，不应该。

声明是

TTestClassClass = class of TTestClass; // note: of TTestClass!

这就是为什么基 TTestClass（它继承自 TObject）的（空）构造函数被调用的原因，因为那是 声明的类TTestClassClass 指的是。

如果你想调用 actual 构造函数，那么你应该在基类中使构造函数 virtual 并 覆盖 在后代中，就像您在问题的最后一部分中所做的那样。

---

FWIW，如果你声明一个

TTestClassDescendantClass = class of TTestClassDescendant;

然后用它来实例化一个后代类，那么你确实应该得到一个TTestClassDescendant 并且构造函数应该显示你所期望的。

类比

但是构造函数的这种行为就像其他非虚拟和虚拟方法一样：

type
  TBase = class
    procedure DoSomething; // outputs: "TBase: Doing something"
  end;

  TDesc = class(TBase)
    procedure DoSomething; // outputs: "Descendant does it now"
  end;

var
  D: TBase;
begin
  D := TDesc.Create;
  D.DoSomething;

由于D 被声明为TBase，对D.DoSomething 的调用将调用TBase.DoSomething，而不是TDesc.DoSomething。

但如果DoSomething 是virtual 并且在TDesc 中覆盖，那么将使用D 中的actual 类。你给出的例子是一样的，除了你在那里使用元类。