使用 Gradle 仅编译时依赖和 ProGuard答案

【问题标题】：Compile time only dependency and ProGuard using Gradle使用 Gradle 仅编译时依赖和 ProGuard
【发布时间】：2014-10-07 07:43:47
【问题描述】：

我正在使用 Gradle 构建一个 Android 库，并且我只有编译时依赖项。

我使用的是 Gradle 0.9+，所以如果我这样做了

android.libraryVariants.all { variant ->
    variant.packageLibrary.exclude( 'libs/libA.jar' )
}

它可以工作，并且 libA.jar 没有打包在我的最终 aar 中。

但是，如果我打开 ProGuard，这将不起作用，并且 libA.jar 正在被打包。

我还通过添加

将这个 jar 排除在混淆之外

-keep class com.libA.** { *; }

到我的 proguard-rules.txt 但它没有任何区别。

我可以看到proguardRelease 任务在所有packageRelease 任务之前执行，但是我不确定我是否可以做任何事情。

这是我的整个构建文件：

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:0.9.+'
    }
}
apply plugin: 'android-library'

repositories {
    mavenCentral()
}

android {
    compileSdkVersion 19
    buildToolsVersion "19.1.0"

    defaultConfig {
        minSdkVersion 8
        targetSdkVersion 19
        versionCode 1
        versionName "1.0"
    }
    buildTypes {
        release {
            runProguard true
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.txt'
        }
    }
}

android.libraryVariants.all { variant ->
    variant.packageLibrary.exclude( 'libs/libA.jar' )
}


dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    compile 'com.android.support:support-v4:20.0.0'
}

有什么方法可以针对 jar 进行编译，但将其从最终包中排除，而无需关闭 ProGuard？

【问题讨论】：

标签： java android gradle proguard android-library

【解决方案1】：

我最近才回到这个并找到了一个解决方法，所以我想我会分享：

我现在将“libs”文件夹添加为本地存储库，所以我的构建文件看起来像这样（我还更新了 Gradle 版本）：

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:0.12.2'
    }
}

apply plugin: 'com.android.library'

repositories {
    jcenter()
    flatDir {
        dirs 'libs'
    }
}

dependencies {
    compile ':libA'
    compile 'com.android.support:support-v4:20.0.0'
}

android {
    compileSdkVersion 19
    buildToolsVersion "19.1.0"

    defaultConfig {
        minSdkVersion 8
        targetSdkVersion 19
        versionCode 1
        versionName "1.0"
    }
    buildTypes {
        release {
            runProguard true
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.txt'
        }
    }
}

依赖解析很好，没有打包在最终的aar中。

另外，我没有在 proguard 文件中包含任何额外内容。

【讨论】：