Delphi 2007 - 将 TDateTimePicker 的焦点设置为进入时的秒数

Question

当控件第一次获得焦点时，有没有办法将 TDateTimePicker（设置为时间选择器）的焦点显式设置为“秒”字段？默认值似乎是“小时”字段。当您在控件之间切换时，控件似乎记得 H、M、S 中的哪一个具有焦点，这没关系，但我希望能够在带有控件的对话框首次显示时将焦点显式设置为秒字段。

This answer 建议切换格式（将焦点初始化到“小时”字段），然后我可以发送两个光标右消息移动到秒字段，但我希望少一些 希斯·罗宾逊。

Answer 1

没有直接的方法，但如果包含以下代码，则可以在 TDateTimePicker 控件中操作焦点的位置：

{$IF CompilerVersion >= 17 }
{$DEFINE D2005UP }
{$ELSE }
{$UNDEF D2005UP }
{$ENDIF }

{$IF CompilerVersion >= 20 }
{$DEFINE D2009UP }
{$ELSE }
{$UNDEF D2009UP }
{$ENDIF }

PROCEDURE SendKeys(CONST Keys : ARRAY OF WORD);
  VAR
    {$IFDEF D2009UP }
    InputEvents : TArray<TInput>;
    {$ELSE }
    InputEvents : ARRAY OF TInput;
    {$ENDIF }
    {$IFNDEF D2005UP }
    I           : INTEGER;
    {$ENDIF }
    Key         : WORD;

  PROCEDURE Add(Key : WORD ; Action : WORD = 0);
    VAR
      INP       : TInput;

    BEGIN
      FillChar(INP,SizeOf(TInput),0);
      INP.Itype:=INPUT_KEYBOARD;
      INP.ki.wVk:=Key;
      INP.ki.wScan:=0;
      INP.ki.dwFlags:=Action;
      INP.ki.time:=0;
      INP.ki.dwExtraInfo:=0;
      {$IFDEF D2009UP }
        InputEvents:=InputEvents+[INP]
      {$ELSE }
        SetLength(InputEvents,SUCC(LENGTH(InputEvents)));
        InputEvents[HIGH(InputEvents)]:=INP
      {$ENDIF }
    END;

  PROCEDURE AddKeyDown(Key : WORD);
    BEGIN
      Add(Key)
    END;

  PROCEDURE AddKeyUp(Key : WORD);
    BEGIN
      Add(Key,KEYEVENTF_KEYUP)
    END;

  PROCEDURE AddKeyPress(Key : WORD);
    BEGIN
      AddKeyDown(Key);
      AddKeyUp(Key)
    END;

  BEGIN
    IF LENGTH(Keys)=0 THEN EXIT;
    {$IFDEF D2005UP }
      FOR Key IN Keys DO AddKeyPress(Key);
    {$ELSE }
      FOR I:=LOW(Keys) TO HIGH(Keys) DO BEGIN
        Key:=Keys[I];
        AddKeyPress(Key)
      END;
    {$ENDIF }
    SendInput(LENGTH(InputEvents),InputEvents[LOW(InputEvents)],SizeOf(TInput));
    Application.ProcessMessages
  end;

PROCEDURE SetDateTimePickerFocus(DTP : TDateTimePicker ; FocusTo : CHAR);
  VAR
    S   : STRING;

  BEGIN
    DTP.SetFocus;
    Application.ProcessMessages;
    S:=DTP.Format; DTP.Format:='HH';
    Application.ProcessMessages;
    DTP.Format:=S;
    Application.ProcessMessages;
    CASE UpCase(FocusTo) OF
      'H' : ; // NOTHING //
      'M' : SendKeys([VK_RIGHT]);
      'S' : SendKeys([VK_RIGHT,VK_RIGHT])
    ELSE // OTHERWISE //
      RAISE ERangeError.Create('Unsupported FocusTo value in SetDateTimePickerFocus: "'+FocusTo+'"')
    END
  END;

{$IFDEF D2005UP }
TYPE
  TDateTimePickerHelper = CLASS HELPER FOR TDateTimePicker
                            PROCEDURE   SetFocusTo(C : CHAR);
                          END;

{ TDateTimePickerHelper }

PROCEDURE TDateTimePickerHelper.SetFocusTo(C : CHAR);
  BEGIN
    SetDateTimePickerFocus(Self,C)
  END;
{$ENDIF }

如果您使用 Delphi 2005 及更高版本，TDateTimePicker 控件还有一个类帮助器。

用法（Delphi 2005 之前）：

SetDateTimePickerFocus(DateTimePicker1,'S'); // 'H', 'M' or 'S' to select field

用法（Delphi 2005+）：

DateTimePicker1.SetFocusTo('S'); // 'H', 'M' or 'S' to select field