Delphi，在 TPointerlist() 处编辑 Tenumstring 中的自动完成访问冲突

Question

在@KenWhite 的this autocomplete example 中，当调用TPointerList()[] 时（通过Windows 自动完成界面），Next 函数存在访问冲突。

D10.1u2、Win10.64

function TEnumString.Next(celt: Integer; out elt;
   pceltFetched: PLongint): HResult;
var
 I: Integer;
wStr: WideString;
begin
 I := 0;
 while (I < celt) and (FCurrIndex < FStrings.Count) do
   begin
     wStr := FStrings[FCurrIndex];
     TPointerList(elt)[1] := PWideChar('abcd');  //access violation
     TPointerList(elt)[1] := CoTaskMemAlloc(8);  //access violation
     TPointerList(elt)[I] := CoTaskMemAlloc(2 * (Length(wStr) + 1)); //access violation
     StringToWideChar(wStr, TPointerList(elt)[I], 2 * (Length(wStr) + 1));
     Inc(I);
     Inc(FCurrIndex);
  end;
 if pceltFetched <> nil then
  pceltFetched^ := I;
 if I = celt then
 Result := S_OK
else
  Result := S_FALSE;
end;

Answer 1

在较新的版本（IIRC XE2 及更高版本）中，您可以按照 Remy 所说的去做，但在 IMO 中您不应该这样做。

在 XE2 之前的版本（或任何版本）中，TPointerList 的定义是：

type
  ...
  TPointerList = array[0..MaxListSize] of Pointer;

在较新的版本中，它是：

type
  TPointerList = array of Pointer;

也就是说，从static数组类型（值类型），现在变成了动态数组类型（引用类型）。将无类型输出参数的地址转换为这样的数组可能会变得很棘手。

定义上的差异解释了为什么在较新的版本中，代码不能正常工作：有一个额外的间接级别。

现在，如果您将以下声明添加到 uAutoComplete.pas 文件：

type
  TPointerList = array[0..65535] of Pointer; // assuming 65536 (2^16) entries are enough

然后文件的其余部分可以保持原来的状态。那么：

TPointerList(elt)[I] := ...

有效，并且不需要您在实际上不是的东西上使用稍微棘手的间接强制转换为 Delphi 动态数组。请注意，这也适用于旧版本。

Answer 2

(elt) 需要是(@elt)，[1] 需要是[I]：

TPointerList(@elt)[I]

那么代码就不再是AV了。

此外，必须使用SysAllocString...() 或CoTaskMemAlloc() 分配输出字符串，因为调用者将使用COM 内存管理器来释放它们。您可以使用 RTL 的 ComObj.StringToLPOLESTR() 函数为您处理该问题，这会生成 Delphi String 的 COM 分配的宽字符串副本：

TPointerList(@elt)[I] := StringToLPOLESTR(FStrings[FCurrIndex]);

或者，您可以简单地获得WideString 的数据指针的所有权，而不是在WideString 已经创建一个副本之后在内存中创建另一个副本：

wStr := FStrings[FCurrIndex];
TPointerList(@elt)[I] := Pointer(wStr);
Pointer(wStr) := nil;