如何为 SOAP 客户端完成 XML

Question

我正在尝试实现一个 SOAP 客户端，以处理该位置的 WSDL 文件描述的 Web 服务的加利福尼亚工资税的电子报告：FSET Service。在这个 WSDL 文件中，有几个模式的引用，包括 http://schemas.xmlsoap.org/ws/2004/08/addressing 的一个模式，它似乎在我的程序到达 OnBeforeExecute 事件之前就停止了它。

为了启动这个项目，我尝试访问在 WSDL 文件中声明的 Ping 函数。

我刚刚获得了一些在 Delphi 中创建 SOAP 客户端的经验。我正在使用 Delphi 2010。这是我为达到这一点所做的。我使用 WSDL 导入器将文件导入到上述地址。它为我创建了一个名为 fsetservice 的单元。然后，我在我的项目中添加了一个表单，并在其中添加了一个 HTTPRIO 组件。我将组件的 WSDLLocation 设置为 WSDL 文件的本地副本，在表单上放置几个 TMemos 以捕获请求和响应标头并添加代码来执行此操作。然后我设置了一个按钮，在它的 OnClick 事件中，我写了这段代码：

procedure TForm1.Button1Click(Sender: TObject);
var sResponse: String;
begin
  sResponse := GetFsetServiceSoap.Ping;
end;

当我单击按钮时，我在到达 HTTPRIO OnBeforeExecute 事件中的断点之前收到此消息：

标题http://schemas.xmlsoap.org/ws/2004/08/addressing:Action 为 最终收件人是必需的，但邮件中不存在

我知道每次发帖我们应该只问一个问题，但有时你的知识不足以问一个好问题：

编辑：为了节省其他有相同问题的人的时间，我将我找到的答案放在这些问题下。

看起来 HTTPRIO 组件可能正在检查从 WSDL 文件导入的 XML 是否与 WSDL 中引用的模式的完整性。这看起来很酷，但这是真的吗？

*回答：不正确，至少根据页面底部http://www.tutorialspoint.com/wsdl/wsdl_definition.htm 的注释。根据注释，模式不必实际存在于该位置，它只需要唯一标识 WSDL 中使用的模式。*

在自动创建（且未修改）的 GetFsetService 函数中，我可以一直走到最后，错误发生在返回时，似乎不可能进入调用错误的实际过程。有没有我想念的方法？

回答：我仍然不确定，但似乎答案是否定的。无论如何，虽然从头开始写会比较乏味，但这比等待 WSDL 向导的奇迹更好。

我是否遗漏了一些说明我需要实现为我自动创建的 FsetService 接口的内容？

回答：显然不是。

我在 Marco Cantu 的《Mastering Delphi 2005》一书中看到，有一个由 Borland 提供的应用程序 (WebAppDbg.exe)，它允许您查看在特定端口上发送的 HTTP。我试过但没有结果。这会有帮助吗？如果有，我应该使用哪个端口？

回答：使用 Fiddler2 工具。很好的发现。

如何解决这个错误？

回答：手工操作。

Answer 1

首先，在处理肥皂和 Web 服务时，我会先将 Fiddler2 和 SoapUI 添加到您的工具库中。

听起来信封标题不完整。根据我使用 D2007 和 WCF Web 服务的经验，Delphi 无法正确构建信封头，因此我不得不拦截调用并添加如下项目：

procedure TMainForm.MyMessageEnvelopeComplete(Sender: TROSOAPMessage);
begin
  Sender.EnvelopeNode.AddAttribute('xmlns:a', 'http://www.w3.org/2005/08/addressing', False);
  Sender.HeaderNode.Add('a:Action').Value := 'http://Testservice.Connect/IConnect/Ping';
  Sender.HeaderNode.Add('a:To').Value := 'http://testservice-pc:2021/WSConnect';
end;

编辑：

如果你想手动构建soap信封和post命令，我已经使用以下代码完成了......

procedure TMainForm.Button5Click(Sender: TObject);
  procedure HandleError(const errorCode: integer);
  var
    errorMessage: AnsiString;
  begin
    SetLength(errorMessage, 256);
    FormatMessage( FORMAT_MESSAGE_FROM_SYSTEM or FORMAT_MESSAGE_FROM_HMODULE,
                   Pointer(GetModuleHandle('wininet.dll')),
                   errorCode, 0, PChar(errorMessage), Length(errorMessage), nil);
    SetLength(errorMessage, StrLen(PChar(errorMessage)));
    raise Exception.Create(errorMessage);
  end;

  function BuildHeader: TStringStream;
  begin
    result := TStringStream.Create('');
    try
      result.WriteString('Content-Type: application/soap+xml;charset=UTF-8;action="http://Thermo.Connect/IHCSConnect/Ping"' + sLineBreak);
    except
      result.Free;
      raise;
    end;
  end;

  function BuildBody: TStringStream;
  begin
    result := TStringStream.Create('');
    with result do
      try
        WriteString('<s:Envelope xmlns:s="http://www.w3.org/2003/05/soap-envelope" xmlns:a="http://www.w3.org/2005/08/addressing">' + sLineBreak);
        WriteString('<s:Header>' + sLineBreak);
        WriteString('<a:Action>http://Thermo.Connect/IHCSConnect/Ping</a:Action>' + sLineBreak);
        WriteString('<a:To>http://thermo-pc:2021/WSHCSConnect</a:To>' + sLineBreak);
        WriteString('</s:Header>' + sLineBreak);
        WriteString('<s:Body>' + sLineBreak);
        WriteString('<Ping xmlns="http://Thermo.Connect">' + sLineBreak);
        WriteString('</Ping>' + sLineBreak);
        WriteString('</s:Body>' + sLineBreak);
        WriteString('</s:Envelope>' + sLineBreak);
      except;
        result.Free;
        raise;
      end;
  end;

var
  InetRoot: HINTERNET;
  InetConnect: HINTERNET;
  Request: HINTERNET;
begin
  InetRoot := InternetOpen('GabeCode', INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);
  try
    InetConnect := InternetConnect( InetRoot, 'thermo-pc:2021', 0, '',
                                    '', INTERNET_SERVICE_HTTP, 0, Cardinal(Self));
    try
      Request := HttpOpenRequest( InetConnect, 'POST', 'WSHCSConnect', 'HTTP/1.1', nil, nil,
                                  INTERNET_FLAG_KEEP_CONNECTION or INTERNET_FLAG_NO_CACHE_WRITE,
                                  0);
      try
        // build add header items to the post request
        with BuildHeader do
        try
          HttpAddRequestHeaders(Request, PChar(DataString), Length(DataString), HTTP_ADDREQ_FLAG_ADD);
        finally
          Free;
        end;

        // build the body of data being posted and send the post
        with BuildBody do
        try
          if not HttpSendRequest(Request, nil, 0, PChar(DataString), Length(DataString)) then
            HandleError(GetLastError);
        finally
          Free;
        end;

      finally
        InternetCloseHandle(Request);
      end;
    finally
      InternetCloseHandle(InetConnect);
    end;
  finally
    InternetCloseHandle(InetRoot);
  end;
end;