对象创建未分配给变量

Question

我想使用类的方法而不将其创建分配给变量。例如：

type
  TMyObject = class
  public
    procedure DoSomething;
  end;

implementation

procedure MyObjDoesSomething;
begin
  TMyObject.Create.DoSomething;
end;

{ TMyObject }

procedure TMyObject.DoSomething;
begin
  // ...
end;

如您所见，在MyObjDoesSomething 中，我没有将TMyObject.Create 分配给TMyObject 变量。

这是否会对内存使用产生某种影响，甚至是我没有想到的其他影响？

Answer 1

是的，影响很大：内存泄漏！

你调用了一个对象的构造函数，但从不释放创建的对象。每次调用 MyObjDoesSomething 时，都会泄漏一个对象实例。

要解决这个问题，你可以像这样创建一个 DoSomething 的类方法：

type
  TMyObject = class
  public
    class procedure DoSomething;
  end;

然后你可以调用 DoSomething 而不创建这样的对象：

procedure MyObjDoesSomething;
begin
  TMyObject.DoSomething;
end;

作为类方法，DoSomething 实现不能使用对象实例变量（字段）。

Answer 2

如果你 Create 一个对象为它分配内存，你必须在使用完对象后调用 Free() 来释放该内存，否则内存泄漏，如果你使用它会随着时间的推移影响内存多次创建这些对象。

如果您不想使用显式变量来引用对象（为什么？），您可以使用 with 块，例如：

procedure MyObjDoesSomething;
begin
  with TMyObject.Create do
  try
    DoSomething;
  finally
    Free;
  end;
end;

另一种选择是让类实现interface，然后您可以让编译器的接口引用计数为您处理释放对象。这比上面的开销要多一点，但是您不必担心手动处理内存，例如：

type
  IMyObject = interface
    ['{896FF4FA-A974-4A8B-9EA5-414C138635E4}']
    procedure DoSomething;
  end;

  TMyObject = class(TInterfacedObject, IMyObject)
  public
    procedure DoSomething;
  end;

implementation

procedure MyObjDoesSomething;
begin
  (TMyObject.Create as IMyObject).DoSomething;
end;

{ TMyObject }

procedure TMyObject.DoSomething;
begin
  // ...
end;

但实际上，只需使用变量即可。使用它无需任何费用：

procedure MyObjDoesSomething;
var
  Obj;
begin
  Obj := TMyObject.Create;
  try
    Obj.DoSomething;
  finally
    Obj.Free;
  end;
end;