检查在线文件是否存在的可靠方法

Question

我有以下代码检查网站上是否存在文件。有时它有效，有时则无效。当它不起作用时，它会调用 EIdHTTPProtocolException 并返回 0，即使该文件存在于服务器上。有谁知道为什么它并不总是有效？如果我在调试代码，它似乎更有可能工作，所以我想知道它是否与时间有关？

这是一个在 Windows 上运行的 FMX 应用程序，我使用的是 Delphi 10.4。

请注意，我已将链接更改为假链接，以便在此处发布，因此很明显，如果您尝试，下面的代码将始终返回 0。

uses IdHTTP, IdStack;

function CheckFileOnlineExists(const OnlineFile: string; var Size: Int64): Byte;
var
 IdHttp: TIdHTTP;
begin
  Result := 0; // File not found
  IdHttp := TIdHTTP.Create(nil);
try
  try
    IdHttp.Head(OnlineFile);
    Size := IdHttp.Response.ContentLength;
    if Size > 0 then Result := 2; // File found
  except
    on E: EIdHTTPProtocolException do ;
    on E: EIdSocketError do Result := 1; // No internet
  end;
finally
  IdHttp.Free;
end;
end;

procedure TMainForm.FormActivate(Sender: TObject);
Var
  LSize : Int64;
  LRes : Byte;
begin
  // Check if online file exists
  LRes := CheckFileOnlineExists('http://websiteurl.com/file_test.png', LSize);
  if (LRes <> 2) or (LSize <> 5497) then begin
    if LRes = 0 then
      Caption := 'Website check file not found. This app will close'
    else
      Caption := 'Internet connection is needed to run this application';
    Close;
  end;
end;

Answer 1

默认情况下，TIdHTTP 收到来自 HTTP 服务器的错误回复时会引发 EIdHTTPProtocolException。异常的ErrorCode 属性将包含服务器的数字错误代码。在这种情况下，404 对应于 not found。你应该专门处理这种情况。

此外，正如 cmets 中的其他内容所述，远程文件可以存在并且大小为 0 字节。所以你不应该使用ContentLength 作为存在的标志。如果TIdHTTP.Head()退出而没有报错，则文件存在，句号。

试试这个：

function CheckFileOnlineExists(const OnlineFile: string; var Size: Int64): Byte;
var
  IdHttp: TIdHTTP;
begin
  try
    IdHttp := TIdHTTP.Create(nil);
    try
      // TODO: set IdHttp.Request.Accept to tell the server which
      // type of file you will accept and nothing else...
      IdHttp.Head(OnlineFile);
      // TODO: verify the Response.ContentType before assuming success,
      // in case the server sends a 200 OK reply containing an HTML
      // login form or error webpage...
      Size := IdHttp.Response.ContentLength;
      Result := 2; // File found
    finally
      IdHttp.Free;
    end;
  except
    on E: EIdHTTPProtocolException do begin
      Result := iif(E.ErrorCode = 404, 0, 3); // 0: File not found; 3: HTTP error
    end;
    on E: EIdSocketError do Result := 1; // No internet
    on E: Exception do Result := 4; // Unknown error
  end;
end;

procedure TMainForm.FormActivate(Sender: TObject);
var
  LSize : Int64;
  LRes : Byte;
begin
  // Check if online file exists
  LRes := CheckFileOnlineExists('http://websiteurl.com/file_test.png', LSize);
  case LRes of
    0: begin
      Caption := 'Website file not found. This app will close';
    end;
    1: begin
      Caption := 'Internet connection is needed to run this application';
    end;
    2: begin
      if LSize = 5497 then Exit;
      Caption := 'File is not the expected size. This app will close';
    end;
    3: begin
      Caption := 'Website file error. This app will close';
    end;
  else
    begin
      Caption := 'Unknown error. This app will close';
    end;
  end;
  Close;
end;

话虽如此，您可以通过以下任一方式避免EIdHTTPProtocolException 因常见错误而引发的开销：

• 在TIdHTTP.HTTPOptions 属性中启用hoNoProtocolErrorException 标志：

function CheckFileOnlineExists(const OnlineFile: string; var Size: Int64): Byte;
var
 IdHttp: TIdHTTP;
begin
  try
    IdHttp := TIdHTTP.Create(nil);
    try
      IdHTTP.HTTPOptions := IdHTTP.HTTPOptions + [hoNoProtocolErrorException];
      // TODO: see above...
      IdHttp.Head(OnlineFile);
      if (IdHttp.ResponseCode div 100) = 2 then
      begin
        // TODO: see above...
        Size := IdHttp.Response.ContentLength;
        Result := 2; // File found
      end
      else if IdHttp.ResponseCode = 404 then
      begin
        Result := 0; // File not found
      end
      else begin
        Result := 3; // HTTP error
      end;
    finally
      IdHttp.Free;
    end;
  except
    on E: EIdSocketError do Result := 1; // No internet
    on E: Exception do Result := 4; // Unknown error
  end;
end;

• 将404（和您感兴趣的任何其他错误代码）传递给TIdHTTP.DoRequest() 的AIgnoreReplies 参数：

type
  TIdHTTPAccess = class(TIdHTTP)
  end;

function CheckFileOnlineExists(const OnlineFile: string; var Size: Int64): Byte;
var
 IdHttp: TIdHTTP;
begin
  try
    IdHttp := TIdHTTP.Create(nil);
    try
      // TODO: see above ...
      TIdHTTPAccess(IdHttp).DoRequest('HEAD', OnlineFile, nil, nil, [404]);
      Result := IdHttp.ResponseCode <> 404;
      if Result then
      begin
        // TODO: see above ...
        Size := IdHttp.Response.ContentLength;
      end;
    finally
      IdHttp.Free;
    end;
  except
    on E: EIdHTTPProtocolException do begin
      Result := 3; // some other HTTP error
    end;
    on E: EIdSocketError do Result := 1; // No internet
    on E: Exception do Result := 4; // Unknown error
  end;
end;