验证动态复选框

Question

我在数据库中有两个表，表 A 和表 B。用户填写表 A，将在表 A 中插入新记录。在表 B 中，表 A 中的记录称为复选框。从此表单中，数据将被插入到表 B 中。以下代码在表单 B 中。在此代码中捕获的数据将被插入到列中（假设列名为 menu_check），结果类似于“value1,value2, value3"（取决于用户选中的复选框数）

<input type="checkbox" name="chckmenu" id="chckmenu" value="#qMenu.menu_id#"   />#qMenu.menu_name_eng#

Form B 完成后，用户将被引导到一个页面，该页面显示 Table B 中所有记录的列表。用户可以从该表中编辑任何记录。类似于用户可以查看、更新或删除任何记录的简单列表。在编辑页面，如何调出menu_check的值，根据列查看是否有checkbox被勾选。

例如：

• 如果 menu_check 中的值为 'value1,value2,value3'，则仅选中第一个、第二个和第三个复选框。
• 如果 menu_check 中的值为 'value1,value3'，则仅选中第一个和第三个复选框。

我尝试使用分隔符，但仍然无法得到它，因为我不知道在此之后从哪里继续。

<cfloop delimiter="," index="a" list="#queryname.menu_check#"></cfloop>

我尝试使用类似的东西；

<input type="checkbox" name="chckmenu" id="chckmenu" value="#qMenu.menu_id#" <cfif "#queryname.menu_check#" EQ "#qMenu.menu_id#">selected</cfif> /> #qMenu.menu_name_eng#

但这也没有用。我正在使用 ColdFusion9。

Answer 1

为了使input[type=checkbox]被选中，你需要使用checked而不是selected。

由于queryname.menu_check 的值，您可以使用listFind(list, value [, delimiters, includeEmptyValues]) 函数检查queryname.menu_check 中是否存在该值。

<cfset checkedstatus = "">
<cfif ListFind(queryname.menu_check, qMenu.menu_id)>
  <cfset checkedstatus = " checked">
</cfif>
<input type="checkbox" name="chckmenu" id="chckmenu" value="#qMenu.menu_id#"#checkedstatus#/> #qMenu.menu_name_eng#

循环中

<cfoutput query="qMenu">
  <cfset checkedstatus = "">
  <cfif ListFind(queryname.menu_check, qMenu.menu_id)>
    <cfset checkedstatus = " checked">
  </cfif>
  <input type="checkbox" name="chckmenu" id="chckmenu" value="#qMenu.menu_id#"#checkedstatus#/> #qMenu.menu_name_eng#
</cfoutput>

Answer 2

扩展RRK's answer，列表（和列表函数）肯定有帮助。但是，我不建议以这种方式实际将数据存储在数据库中。取而代之的是use a junction or bridge table，它提供了比列表更大的灵活性和性能。

Sample Table Structure

• 用户 - 唯一用户表
• 菜单 - 独特的菜单选项表
• UserMenu - 每个用户的选定菜单选项表

请注意，联结表将每个选择存储为单独的行。这样，您可以根据需要存储尽可能少或尽可能多的选择，并轻松更改它们。

使用该结构，编辑页面只检索当前用户的选定选项并将这些值转换为列表。

 <cfquery name="qSelectedOptions" ...>
     SELECT MenuId
     FROM   UserMenu 
     WHERE  UserId = <cfqueryparam value="#form.currentUserID#" .... >
 </cfquery>

 <cfset selectedOptions = valueList(qSelectedOptions.MenuId)>

然后在生成复选框的循环中，一个简单的列表函数确定是否应选中每个框：

 <cfquery name="qMenu" ...>
     SELECT MenuId, MenuName
     FROM   Menu
     ORDER BY MenuName
 </cfquery>

 <cfoutput query="qMenu">
     #MenuName# 
     <input type="checkbox" name="menuOptions" value="#MenuId#" 
         <cfif listFind(selectedOptions, menuId)>checked</cfif>>
 </cfoutput>

最后，要将选择保存到数据库，首先删除现有值，然后插入任何新值。

   <cftransaction>
       <cfquery ....>
         DELETE FROM UserMenu 
         WHERE  UserId = <cfqueryparam value="#form.currentUserID#" cfsqltype="...">
       </cfquery ....>
       <cfquery ....>
          INSERT INTO UserMenu (UserID, MenuID)
          SELECT <cfqueryparam value="#form.currentUserID#" cfsqltype="...">
                     , MenuId
          FROM   Menu
          WHERE  MenuId IN (
             <cfqueryparam value="#form.menuOptions#" list cfsqltype="...">

          )
       </cfquery>
    </cftransaction>

Answer 3

我已经设法解决了这个问题。我正在使用 CONTAIN 检查数据库中是否存在该值。我的代码行；

<input type="checkbox" name="chckmenu" id="chckmenu" value="#qMenu.menu_id#"  
<cfif qSubCheck.con_check CONTAINS #qMenu.menu_id#>Checked</cfif>
/>#qMenu.menu_name_eng#

感谢大家的帮助！