excel中的整数之和答案

【问题标题】：Sum of integers in excelexcel中的整数之和
【发布时间】：2021-06-21 15:09:21
【问题描述】：

我在 excel 中有一个简单的查询。我想将三个不同工作表中的数字总和放入第四个 Excel 工作表中。当一个单元格具有 NULL 值（如减号）时，我会收到一条错误消息。

Sheet1 = 1

表 2 = 2

表 3 = -

Sheet4 = Sheet1!A1+Sheet2!A1+Sheet3!A1

我想要 3 作为答案，但我收到 #Value 错误消息。如何调整配方？

【问题讨论】：

标签： excel

【解决方案1】：

如果工作表是连续的并且您可以使用：

=SUM(Sheet1:Sheet3!A1)

Sheet1 是最左边的，Sheet 3 是最右边的三张表，Sheet2 介于两者之间。

如果表格不连续，那么您可以使用：

=SUMPRODUCT(SUMIF(INDIRECT("'"&{"Sheet1","Sheet2","Sheet3"}&"'!A1"),"<>"))

使用 Office 365 及其动态数组，我们可以简化第二个：

=SUM(INDIRECT("'"&{"Sheet1","Sheet2","Sheet3"}&"'!A1"))

【讨论】：

谢谢，但我有不同的工作表名称。在实际文件中，我有公式； =SUM('CAT I'!O7+'CAT II'!O7+'CAT III'!O7+CATIV!O7+CATIVb!O7)
没关系，只需将Sheet# 换成正确的工作表名称即可。它将使用不同的工作表名称。所以间接部分是INDIRECT("'"&{"CAT I","CAT II","CAT III","CATIV","CATIVb"}&"'!O7")
以及 3D 总和，如果连续的话：=SUM('CAT I':'CATIVb'!O7)
嗨，斯科特。感谢您的解决方案。小评论。使用连续文件，您提到的公式只需稍作更改，否则会给出错误消息 #NAME？调整后的公式为： =SUM('CAT I:CATIVb'!O7) 其次，没有连续文件的其他公式仅适用于一个单元格。如果我将公式拖到其他单元格，则 O7 的值不会自动更改。您也可以为此提供解决方案吗？
用于 INDIRECT 使其可拖动：INDIRECT("'"&{"CAT I","CAT II","CAT III","CATIV","CATIVb"}&"'!O"&ROW(O7)

【解决方案2】：

检查空单元格值是否为数字格式。也许“-”是文本值，所以你会得到 #Value 错误

【讨论】：

【解决方案3】：

因此，如果您想将某个取其值给出错误的东西视为 0（否则只取其值），您可以使用 iferror 函数执行此操作。然后，您可以按如下方式建立您的总和。我不反对使用 SUM 的提议。我正在显示一个选项，并让您将 IFERROR 添加到您的曲目中。

=iferror(value(Sheet1!A1),0)+iferror(value(Sheet2!A1),0)+iferror(value(Sheet3!A1),0)

【讨论】：

嗨杰里米。您的公式不起作用，但如果我将其更改为以下公式，它会起作用； =IF(ISNUMBER(CATI!A1),CATI!A1,0)+IF(ISNUMBER(CATII!A1),CATII!A1,0)+IF(ISNUMBER(CATIII!A1),CATIII!A1,0)跨度>
完整披露：我在 Google 表格上对其进行了测试，它确实有效。它在 Excel 上做了什么？我可以删除或修改它。我刚刚在 LibreOffice calc 上进行了测试，它也在那里工作。
你好。对不起，这是我的错。我写错了。现在我再次检查，它的工作原理。感谢您提醒我以及您为支持我所做的努力:-)。