如何检查变量是否包含批处理文件中的特殊字符

Question

如何检查批处理文件中的变量是否包含特殊字符？ 例如，如果我的变量包含文件名，则文件名不应包含 \/ < > | : * " ? 这些字符。

@echo off
set param="XXX"
echo %param%| findstr /r "^[^\\/?%*:|"<>\.]*$">nul

if %errorlevel% equ 0 goto :next
echo "Invalid Attribute"

:next
echo correct

我用这个链接作为参考regex for validating folder name & file name

Answer 1

你不能使用echo %param%| findstr /r ... 甚至echo !param!| findstr /r ...。有关如何解析和处理管道的更多信息，请查看以下问题和答案：Why does delayed expansion fail when inside a piped block of code。

使用辅助（临时）文件如下：

@ECHO OFF
SETLOCAL EnableExtensions EnableDelayedExpansion
:testloop
  set "param="
  set /P "param=string to test (hit <Enter> to end)> "
  if not defined param goto :endtest
  >"%temp%\33605517.txt" echo(!param!

  rem next line for debugging purposes
  for /F "usebackq delims=" %%G in ("%temp%\33605517.txt") do set "_marap=%%G"

  findstr /r ".*[<>:\"\"/\\|?*%%].*" "%temp%\33605517.txt" >nul 

  if %errorlevel% equ 0 (
    echo !errorlevel! Invalid !param! [!_marap!]
  ) else (
    echo !errorlevel! correct !param! [!_marap!]
  )
  goto :testloop
:endtest
ENDLOCAL
goto :eof

.*[<>:\"\"/\\|?*%%].*正则表达式解释：

• .* - 字符串前面的任何字符出现零次或多次；
• [<>:\"\"/\\|?*%%] 保留字符集中的任意一个字符：
  • <（小于）；
  • >（大于）；
  • :（冒号）；
  • "（双引号）转义为 \"\"（findstr 和批处理解析器）；
  • /（正斜杠）；
  • \（反斜杠）转义为\\（findstr）；
  • |（竖条或竖管）；
  • ?（问号）；
  • *（星号）；
  • %（百分号）转义为%%（对于批处理解析器）；事实上，% is not reserved for NTFS file system 但需要在纯 cmd 和/或批处理脚本中进行特殊转义；
• .* - 字符串末尾的任何字符出现零次或多次。

这里有更多关于 SO 的问题的链接，其中包含 Aacini、DBenham、Jeb（以及其他人）的详尽答案。令人兴奋，引人入胜的阅读......

• How does the Windows Command Interpreter (CMD.EXE) parse scripts?
• Why does delayed expansion fail when inside a piped block of code?

以及由 David Deley 提供的详细信息 How Command Line Parameters Are Parsed，© 2009（2014 年更新）

输出：

string to test (hit <Enter> to end)> n<m
0 Invalid n<m [n<m]
string to test (hit <Enter> to end)> n>m
0 Invalid n>m [n>m]
string to test (hit <Enter> to end)> n:m
0 Invalid n:m [n:m]
string to test (hit <Enter> to end)> n/m
0 Invalid n/m [n/m]
string to test (hit <Enter> to end)> n\m
0 Invalid n\m [n\m]
string to test (hit <Enter> to end)> n|m
0 Invalid n|m [n|m]
string to test (hit <Enter> to end)> n?m
0 Invalid n?m [n?m]
string to test (hit <Enter> to end)> n*m
0 Invalid n*m [n*m]
string to test (hit <Enter> to end)> n"m
0 Invalid n"m [n"m]
string to test (hit <Enter> to end)> nm
1 correct nm [nm]
string to test (hit <Enter> to end)> nm.gat
1 correct nm.gat [nm.gat]
string to test (hit <Enter> to end)> n%m.gat
0 Invalid n%m.gat [n%m.gat]
string to test (hit <Enter> to end)>

Answer 2

您可以将 findstr 行更改为

set "param=Test < string"

cmd /v:on /c echo(^^!param^^! | findstr /r "^[^\\/?%%*:|<>\.\"]*$^" > nul

if %errorlevel% equ 0 ( 
echo OK
) ELSE (
  echo Invalid, special character found
)

这行得通，因为参数将在子 cmd.exe 进程中扩展，扩展延迟。
是否启用延迟扩展并不重要，该线路始终有效。
而且我更改了正则表达式，因为搜索报价本身有点讨厌。