在vbscript中读取文本文件的某一行答案

【问题标题】：Reading a certain line of a text file in vbscript在vbscript中读取文本文件的某一行
【发布时间】：2015-10-15 15:58:01
【问题描述】：

有没有办法使用 vbscript 读取文本文件的某一行并将其存储为变量。谢谢。

【问题讨论】：

见stackoverflow.com/questions/15533214/…
blogs.technet.com/b/heyscriptingguy/archive/2005/01/25/…
谢谢 JNevill，作为对 John Coleman 的回复，我花了大约一个小时寻找答案，但无济于事，这就是为什么我在这里发布我的问题，以便可能有好心人让我的生活更轻松一些，并阻止我花费数小时搜索网络。
@JosephBunce 如果您确实阅读了 JNevill 或 Phylogenesis 提供的链接，那么您会看到他们回答了您的问题。
@Sylverac 我已经阅读了它们并且确实如此，这就是我感谢 JNevill 的原因

标签： vbscript

【解决方案1】：

试试这个例子：

Option Explicit
Dim ws,MyFile
Set ws = CreateObject("WScript.Shell")
MyFile = "%Windir%\system32\slmgr.vbs"
MyFile = ws.ExpandEnvironmentStrings(MyFile)
wscript.echo ExtractLinesFromTextFile(Myfile,1,2) 'Extract line from line 1 to 2
wscript.echo ExtractLinesFromTextFile(Myfile,2,2) 'Extract line N°2
wscript.echo ExtractLinesFromTextFile(Myfile,1,5) 'Extract line from line 1 to 5
wscript.echo ExtractLinesFromTextFile(Myfile,1,10)'Extract line from line 1 to 10
wscript.echo ExtractLinesFromTextFile(Myfile,8,20)'Extract line from line 8 to 20
wscript.echo ExtractLinesFromTextFile(Myfile,8,40)'Extract line from line 8 to 40
wscript.echo ExtractLinesFromTextFile(Myfile,8,50)'Extract line from line 8 to 50
'*********************************************************************************************************
Public Function ExtractLinesFromTextFile(ByRef TextFile, ByRef FromLine, ByRef ToLine) '<-- Inclusive
    If FromLine <= ToLine Then
        With CreateObject("Scripting.FileSystemObject").OpenTextFile(TextFile)
            Do Until .Line = FromLine Or .AtEndOfStream
                .SkipLine
            Loop
            Do Until .Line > ToLine Or .AtEndOfStream
                ExtractLinesFromTextFile = ExtractLinesFromTextFile & (.ReadLine & vbNewLine)
            Loop
        End With
    Else
        MsgBox "erreur de depassement de lignes", vbCritical, "erreur de depassement de lignes"
    End If
End Function
'*********************************************************************************************************

【讨论】：