xslt 复制子注释并添加额外的节点

Question

对于以下xml：

<root>
    <employees>
        <employee>
            <Name>ABC</Name>
            <Dept>CS</Dept>
            <Designation>sse</Designation>
        </employee>
    </employees>
</root>

我用这个 xslt：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <!-- Identity transform -->
    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="Name">
        <xsl:copy-of select="."/>
        <Age>34</Age>
    </xsl:template>

    <xsl:template match="Dept">
       <xsl:copy-of select="."/>
        <Domain>Insurance</Domain>
    </xsl:template>
</xsl:stylesheet>

我想实现如下输出

   <employee>
       <Name>ABC</Name>
       <Age>34</Age>
       <Dept>CS</Dept>
       <Domain>Insurance</Domain>
       <Designation>sse</Designation>
   </employee>

我不知道我应该使用什么 xpath 来将结果仅限于员工节点。

Answer 1

嗯，处理从/ 表示的文档节点（根节点）开始，因此如果您编写模板

<xsl:template match="/">
  <xsl:apply-templates select="//employee"/>
</xsl:template>

您仅使用其余模板处理文档的任何 employee 后代。

请参阅https://xsltfiddle.liberty-development.net/pPqsHT6 以获取集成到您的样式表中的上述建议的工作演示，整个代码是

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <!-- Identity transform -->
    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="Name">
        <xsl:copy-of select="."/>
        <Age>34</Age>
    </xsl:template>

    <xsl:template match="Dept">
       <xsl:copy-of select="."/>
        <Domain>Insurance</Domain>
    </xsl:template>

    <xsl:template match="/">
      <xsl:apply-templates select="//employee"/>
    </xsl:template>

</xsl:stylesheet>