在 VBA Excel 中以编程方式将选项按钮添加到用户窗体

Question

我对 VBA 编程非常陌生。 我的场景是我将获得一个字符串值列表我需要使用小窗口上的单选按钮向用户显示这些值，以便每当用户通过单击单选按钮选择任何值时，我应该能够获得该值在 VBA 代码中。我在互联网的用户表单中搜索添加选项按钮，我得到了一些使用 GUI 方法创建选项按钮的解决方案。但我需要通过程序完成。我在 * (How can I dynamically add a radio button on a form using VBA) 中找到了一个有用的线程，我使用了这个，但我仍然无法在用户表单上获得任何标签或按钮，将显示一个普通的用户表单。因此，请任何人提供有关此的信息。

代码是：

Sub Button1_Click()
    lResult As Variant    ' this is a array which contains string vaues to be dispayed as radio button.

    ' Some operatin is done here to get the list of values in lResult

    Dim rad As Variant
    Set rad = UserForm1.Controls.Add("Forms.OptionButton.1", "radioFoo", True)
    rad.Caption = "bar"
    rad.Left = 10
    rad.Width = 10
    rad.Top = 10
End Sub

UserForm1 是我使用 VBA 菜单栏中的插入选项创建的用户表单。 我试图在用户窗体上添加一个按钮。我没有在用户窗体上使用初始化功能。 excel 表 Button1 上有一个按钮，我在单击该按钮时调用此函数。

谢谢

Answer 1

如果您有一个名为 UserForm1 的表单，其中包含一个名为 CommandButton1 的按钮

您可以为您的用户窗体设置 Initialize 方法以编程方式创建一组单选按钮

Private Sub UserForm_Initialize()
    Dim OptionList(1 To 3) As String
    Dim btn As CommandButton
    Set btn = UserForm1.CommandButton1
    Dim opt As Control
    Dim s As Variant
    Dim i As Integer

    OptionList(1) = "Option 1"
    OptionList(2) = "Option 2"
    OptionList(3) = "Option 3"

    For Each s In OptionList
        Set opt = UserForm1.Controls.Add("Forms.OptionButton.1", "radioBtn" & i, True)
        opt.Caption = s
        opt.Top = opt.Height * i
        opt.GroupName = "Options"

        UserForm1.Width = opt.Width
        UserForm1.Height = opt.Height * (i + 2)

        i = i + 1
    Next

    btn.Caption = "Submit"
    btn.Top = UserForm1.Height - btn.Height + (0.5 * opt.Height)
    btn.Left = (UserForm1.Width * 0.5) - (btn.Width * 0.5)

    UserForm1.Height = UserForm1.Height + btn.Height + (0.5 * opt.Height)
End Sub

Private Sub CommandButton1_Click()
    Dim i As Integer

    For i = 0 To UserForm1.Controls.Count - 1
        If UserForm1.Controls(i) Then
            SelectedOption = UserForm1.Controls(i).Caption
        End If
    Next

    UserForm1.Hide
End Sub

如果您想从工作表中提取列表，您可以更改

Dim OptionList(1 To 3) As String

OptionList(1) = "Option 1"
OptionList(2) = "Option 2"
OptionList(3) = "Option 3"

从这样的范围中提取

Dim OptionList() as Variant
OptionList = Range("A1:A3")

在存储在模块中的“button_onclick()”过程中添加以下代码：

'This is set by the code in UserForm1
Public SelectedOption As String

Sub Button1_OnClick()
    UserForm1.Show
    MsgBox SelectedOption
End Sub

这会给你这个结果：

当您点击提交时，会弹出一个消息框，显示您选择了哪个选项

Answer 2

请记住，在使用选项按钮时，您的选项按钮需要共享相同的 GroupName。
您的控件名称仅供您参考以进行更改/阅读。
您的 Caption 是一个字符串，显示在您的用户表单上给用户。
您的 GroupName 是一个字符串，它允许 Excel 识别选项按钮链接在一起。

因此，如果 opt1 的 GroupName 为“1”而 opt2 的 GroupName 为“2”，那么您将能够选择两者，因为它们位于不同的组中。

Private Sub UserForm_Initialize()
    Dim opt1 As Control, opt2 As Control

    Set opt1 = UserForm1.Controls.Add("Forms.OptionButton.1", , True)
    With opt1
        .Name = "radioFoo"
        .GroupName = "1"
        .Caption = "Option 1"
    End With

    Set opt2 = UserForm1.Controls.Add("Forms.OptionButton.1", , True)
    With opt2
        .Name = "radioFoo2"
        .GroupName = "1"
        .Caption = "Option 2"
        .Left = 100
    End With

End Sub

编辑：
从看到您编辑的帖子和您的评论...
不，您不需要 UserForm_Initialize() 方法。

它是一个名为 Event 的 Excel-VBA 功能。
它的用途是指定用户表单在初始化用户表单（第一次启动）时执行某些操作。
与您的代码类似，Button1_Click() 也是一个事件。
由于您告诉 Excel 在用户单击 Button1 的事件中执行以下操作...

无论如何，让我简单地向您解释一下选项按钮的作用。
一组选项按钮强制用户从程序提供的选项中只选择一个选项。
VBA 中的选项按钮只允许您创建一个选项。因此，如果要创建 2 个选项，则必须创建 2 个选项按钮。
但是只有一个问题：如果您想创建 2 组选项按钮，以便用户可以选择 2 个单独的选项，该怎么办？例如，食物和饮料？
VBA 为我们提供了一个名为GroupName 的选项按钮的属性。 GroupName 允许 VBA 区分不同的选项按钮组。
因此，在您创建的每个选项按钮中，必须初始化其 GroupName 值。如果您看到没有 GroupName 的选项按钮的任何实现，那么您就是在玩火。

那么，最后让我们看看你的代码：

Sub Button1_Click()
    ' Some operatin is done here to get the list of values in lResult

    Dim rad1 As Control, rad2 As Control
    Set rad1 = UserForm1.Controls.Add("Forms.OptionButton.1", "radioFoo1", True)
    rad1.Caption = "bar"
    rad1.Left = 10
    rad1.Width = 10
    rad1.Top = 10
    rad1.GroupName = "Group1"

    Set rad2 = UserForm1.Controls.Add("Forms.OptionButton.1", "radioFoo2", True)
    rad2.Caption = "foo"
    rad2.Left = 10
    rad2.Width = 10
    rad2.Top = 50
    rad2.GroupName = "Group1"
End Sub

只有一件事：
- 正如我之前隐含提到的，只有一个选项的选项按钮没有任何意义。如果您正在寻找开/关类型的功能，您不妨选择复选框。
因此，我创建了另一个选项按钮，将其定义为与您创建的第一个选项按钮位于同一组中（ rad1)。

希望对您有所帮助。

干杯，
公园

当问题/问题得到解答/解决后，请务必选择最佳答案。 谢谢。