VBA在最后一个真实条件下退出循环

Question

我正在构建一个宏，该宏将在文件夹中查找特定报告类型的所有 xls 文件，并将它们与整个路径一起列在工作表中。然后它按升序对它们进行排序并找到最新的文件，打开该文件并将其中的信息复制到一个空白文件中，作为聚合来自多种报告的最新数据的过程。

问题是在找到最新文件后退出循环：

Dim i As Variant
Dim myarray() As Integer
Dim myarray2() As Variant

i = 0

For Each cell In Range("C1:C" & x)
    If InStr(1, cell, "proof") Then
        i = i + 1
        Debug.Print i & " " & cell.value
        ReDim myarray(i)
        ReDim Preserve myarray2(cell)
    End If

    Do
    Loop Until InStr(1, cell, "proof")
Next cell

这是一个试用代码 - 它会在指定文件夹中查找文件名中包含 "proof" 的所有文件，然后在即时窗口中打印它们。动态数组存储每个文件名，直到循环结束，Do Until 循环例程应该在最后一个检查为真的条件下停止它——它将被打开并从中复制信息的文件。问题是Do Until 循环锁定了整个例程，因为第一次迭代是真的会满足它，我不知道如何让它退出它应该在的地方......

Do-While 循环放在同一个位置时只会自行循环。

Answer 1

不要真正达到你的全部目标。但你可以先试试这个

Option Explicit

Sub main()
    Dim i As Variant
    Dim myarray() As String
    Dim cell As Range
    Dim firstAddress As String
    Dim nFound As Long

    With Range("C1", Cells(Rows.Count, "C").End(xlUp)) '<--| reference column "C" cells from row 1 down to last non empty one
        nFound = WorksheetFunction.CountIf(.Cells, "*proof*") '<--| count occurrences of wanted substring
        If nFound = 0 Then Exit Sub '<--| exit if no occurrences
        ReDim myarray(1 To nFound) '<--| size your array to match occurrences
        Set cell = .Find(what:="proof", after:=.Cells(.Rows.Count, 1), LookIn:=xlValues, lookat:=xlPart, searchdirection:=xlNext) '<--| find first occurrence
        firstAddress = cell.Address '<--| store first occurrence address
        Do
            i = i + 1 '<-- update array index
            myarray(i) = cell.Value '<--| update array current index content
            Set cell = .FindNext(cell) '<--| search for next occurrence
        Loop While cell.Address <> firstAddress '<--| exit if occurrence wrapped back to the first one
    End With
End Sub