VBA中的列比较错误

Question

您好，我正在编写一个宏，用于比较 Excel 中不同工作表上的两列。 宏如下：

Sub Main()
Application.ScreenUpdating = False

    Dim stNow As Date
    stNow = Now

    Dim arr As Variant
    arr = Worksheets("Sheet2").Range("W3:W" & Range("W" & Rows.Count).End(xlUp).Row).Value

    Dim varr As Variant
    varr = Worksheets("Sheet3").Range("P3:P" & Range("P" & Rows.Count).End(xlUp).Row).Value

    Dim x, y, match As Boolean
    For Each x In arr
        match = False
        For Each y In varr
            If x = y Then match = True
        Next y
        If Not match Then
            Worksheets("Sheet1").Range("L" & Range("L" & Rows.Count).End(xlUp).Row + 1) = x
        End If
    Next

    Debug.Print DateDiff("s", stNow, Now)
Application.ScreenUpdating = True
End Sub

如果列在同一张纸上并且代码中没有图纸引用，则它可以完美运行。但现在它只复制 Sheet3 列 W 中的第一个单元格，尽管该值已经存在于 Sheet3 的 P 列中。

Answer 1

如您所见，当没有工作表引用时，它可以正常工作。

您需要始终限定Range()、Rows. 和Columns.，否则它将使用ActiveSheet 是什么。

以下内容应该适合您。

Sub Main()
Application.ScreenUpdating = False

Dim stNow   As Date
stNow = Now

Dim arr     As Variant
With Worksheets("Sheet2")
    arr = .Range("W3:W" & .Range("W" & .Rows.Count).End(xlUp).Row).Value
End With

Dim varr    As Variant
With Worksheets("Sheet3")
    varr = .Range("P3:P" & .Range("P" & .Rows.Count).End(xlUp).Row).Value
End With

Dim x, y, match As Boolean
For Each x In arr
    match = False
    For Each y In varr
        If x = y Then
            match = True
            Exit For
        End If
    Next y
    If Not match Then
        With Worksheets("Sheet1")
            .Range("L" & .Range("L" & .Rows.Count).End(xlUp).Row + 1) = x
        End With
    End If
Next

Debug.Print DateDiff("s", stNow, Now)
Application.ScreenUpdating = True
End Sub

注意：我添加了With 语句以减少使用Worksheets("Sheetx"). 的重复性，此外，根据@ScottCraner 的评论更新了If x = y 语句。

我还看到您有一些未声明的变量。我建议将Option Explicit 添加到最开始（Sub Main() 之前）并声明所有变量。

Answer 2

按照@BruceWayne 的回答，您可以替换代码的中间部分，而不是使用 2 x For 循环扫描每个数组内的所有元素，您只能有 1 个 @987654322 @循环，另一个将使用Application.Match函数来查找数组之间的匹配。

这应该会在比较大尺寸数组时为您节省大量代码运行时间。

注意：我已将您的 match 变量替换为 isMatch ，match 不是变量的最佳名称（因为有同名的函数）

编辑 1：删除了 isMatch 变量，因为它不需要。

子代码

Dim x
For Each x In arr
    If IsError(Application.Match(x, varr, 0)) Then '<-- no match between elements inside arrays
        With Worksheets("Sheet1")
            .Range("L" & .Range("L" & .Rows.Count).End(xlUp).Row + 1) = x
        End With
    Else '<-- there is a match between arrays
        ' do nothing , raise a "MsgBox"
    End If       
Next x