VBA Excel - 计算包含特定日期的行

Question

我正在努力想出正确的逻辑：

工作表 1

 A   |     B
------------------ 
test | 01/01/2020
test | 01/01/2020
test | 02/01/2020
test | 03/01/2020

所以我要做的是遍历 B 列日期，然后计算该日期存在多少行。它会打印出类似的东西

工作表2：

 A   |     B
------------------ 
01/01/2020 | 2
02/01/2020 | 1
03/01/2020 | 1

我在想 A 列是否需要将每个日期绑定到字典然后进行计数？使用 VBA 最有效的方法是什么

Answer 1

带计数的唯一字典

• 通过以下方式使用字典，可以在写入的同时，将每个键(Key)的计数写入其值(.item(Key))

守则

Option Explicit

Sub writeUniqueCount()
    
    ' Define Source Column Range.
    Dim rng As Range
    Set rng = ThisWorkbook.Worksheets("Sheet1").Range("A1:A10")
    ' Write Source Column Range to Data Array.
    Dim Data As Variant
    Data = rng.Value
    With CreateObject("Scripting.Dictionary")
        ' Write unique values from Data Array to Unique Dictionary.
        Dim Key As Variant
        Dim i As Long
        For i = 1 To UBound(Data, 1)
            Key = Data(i, 1)
            If Not IsError(Key) And Not IsEmpty(Key) Then
                .Item(Key) = .Item(Key) + 1 ' Count!
            End If
        Next i
        ' Validate Unique Dictionary.
        If .Count = 0 Then
            Exit Sub
        End If
        ' Write values from Unique Dictionary to two-column Data Array:
        ' first column are the keys, second column is the count of each key.
        ReDim Data(1 To .Count, 1 To 2)
        i = 0
        For Each Key In .keys
            i = i + 1
            Data(i, 1) = Key
            Data(i, 2) = .Item(Key)
        Next Key
    End With
    ' Write values from two-column Data Array to two-column Target Range.
    With ThisWorkbook.Worksheets("Sheet1").Range("B1")
        Set rng = .Resize(UBound(Data, 1), 2)
    End With
    rng.Value = Data
    
End Sub