如何在 Scheme 语言的 do-loop 中增加计数器？

Question

我想在 Scheme 语言的 do-loop 中做一个简单的计数器加一，但我对该语言不太熟悉，并且尝试了许多脚本但没有成功。该代码将在 Ansys Fluent 中实现以读取多个案例文件：

(define j 5)
(Do ((i 10 (+ i 1))) ((>= i 20))
(ti-menu-load-string (format #f "/file/read-case \"C:/DataProcessing/Case~a-time~a-sec/test/Case~a-time~a-sec.cas\"" i j i j))
(set! j (+ j 1))
)

如何将新的j 值传递给do-loop，以便我将文件夹和文件名更改如下：

Case10-time5-sec
Case11-time6-sec
...

我知道(set! j (+ j 1)) 不是正确的做事方式，而是让您了解我正在尝试做的事情。我觉得改变值的时候调用变量应该不难吧？

Answer 1

在带有 vars 的列表中，您只需添加另一个术语：

(do ((i 10 (+ i 1))
     (j 5  (+ j 1)))
    ((>= i 20) 'my-return-value)
  (ti-menu-load-string 
   (format #f "/file/read-case \"C:/DataProcessing/Case~a-time~a-sec/test/Case~a-time~a-sec.cas\"" i j i j)))
; ==> my-return-value (and as side effect prints some strings)

知道do 只是递归函数的语法糖。你可以在没有它的情况下使用名为let：

(let function-name ((i 10) (j 5))
  (if (>= i 20)
      'my-return-value
      (begin 
        (ti-menu-load-string 
         (format #f "/file/read-case \"C:/DataProcessing/Case~a-time~a-sec/test/Case~a-time~a-sec.cas\"" i j i j))
        (function-name (+ i 1) (+ j 1)))))

其实你可以把生产和印刷分开来让它发挥作用：

(define (make-strings)
  (let function-name ((i 10) (j 5) (result '()))
    (if (>= i 20)
        (reverse result)
        (function-name 
         (+ i 1) 
         (+ j 1) 
         (cons (format #f "/file/read-case \"C:/DataProcessing/Case~a-time~a-sec/test/Case~a-time~a-sec.cas\"" i j i j)
               result)))))

(for-each ti-menu-load-string (make-strings))

这样做的好处是您可以对make-strings 进行单元测试，扩展它以获取输入变量等。