vba循环不检查重复的零件号答案

【问题标题】：vba loop no checking for duplicate part numbervba循环不检查重复的零件号
【发布时间】：2021-11-05 04:59:47
【问题描述】：

我需要我的循环来检查现有的零件编号，并且只有在没有现有零件编号的情况下才能将其添加到我的表中。如果部件号已经存在，有一个消息框说明它已经存在。将它添加到我的表中就好了，但如果已经有一个现有的部件号，它不会给我消息框。

Private Sub Add_Click()

Dim ws As Worksheet
Set ws = Sheet4
Dim X As Integer
Dim lastrow As Long
Dim PartColumnIndex As Integer
Dim DescriptionColumnIndex As Integer

Const Part = "CM ECP"
Const Description = "Material Description"

Dim PartNum As String
Dim MaterailDescription As String

Dim tbl As ListObject

Set tbl = ws.ListObjects("Master")
Dim newrow As ListRow
Set newrow = tbl.ListRows.Add

With ws
    On Error Resume Next
    Let PartColumnIndex = WorksheetFunction.Match(PartNum, .Rows(2), 0)
    Let DescriptionColumnIndex = WorksheetFunction.Match(MaterialDecription, .Rows(2), 0)
    Let lastrow = .Cells(.Rows.Count, PartColumnIndex).End(xlUp).Row
    
    X = 3
    
    Do
        Let PartValue = .Cells(X, PartColumnIndex).Value
        Let DecriptionColumnIndex = .Cells(X, DecriptionColumnIndex).Value
        If TextBox1.Value = PartValue Then
            MsgBox "Part Number " + TextBox1.Value + " already exists. Please try again or return to main screen."
        ElseIf TextBox1.Value <> PartValue Then
            With newrow
                .Range(1) = TextBox1.Value
                .Range(2) = TextBox2.Value
            End With
        ElseIf X < lastrow Then
            X = X + 1
        
            
        End If
                 
        
    
    Loop Until X > lastrow

    End With

【问题讨论】：

当您在检查PartValue 的If 行上放置断点时，您要比较的值是什么？一个是字符串，另一个不是字符串吗？
我从来没有将 textbox1 设置为任何东西。它是一个数字，但我想它也可以作为字符串读取。 PartValue 是一个字符串
另外，删除On Error Resume Next，因为这可能隐藏了你不应该忽略的各种问题。
@braX - 有点尖锐的评论。你假设每个人都有经验debugging VBA。 OP 在这里是因为他们不知道下一步该做什么......
我不同意将任何插件用于开发目的，但这只是我的意见。开始时有一个学习曲线，绕过该曲线以替换为非标准插件（您的同事都没有）可能不是最好的学习方式......当 VBA 新手时，我和无数人其他人发现后期大师Chip Pearson's website 是一个巨大的帮助（例如"Debugging VBA"。也可能是this

标签： excel vba do-loops

【解决方案1】：

在决定是否添加新行之前扫描表中的所有行，并始终将 Use Option Explicit 添加到代码顶部以捕获诸如DecriptionColumnIndex（无s）之类的错误。

Option Explicit

Sub Add_Click()

    Const PART = "CM ECP"
    Const DESCRIPTION = "Material Description"

    Dim ws As Worksheet
    Dim X As Integer, lastrow As Long
    Dim PartColumnIndex As Integer, DescrColumnIndex As Integer
    Dim PartNum As String, MaterialDescription As String
    Dim tbl As ListObject, bExists As Boolean
    
    Set ws = Sheet1
    Set tbl = ws.ListObjects("Master")
    With tbl
        
        PartColumnIndex = .ListColumns(PART).Index
        DescrColumnIndex = .ListColumns(DESCRIPTION).Index
        
        PartNum = Trim(TextBox1.Value)
        MaterialDescription = Trim(TextBox2.Value)
        
        ' search
        With .DataBodyRange
            lastrow = .Rows.Count
            For X = 1 To lastrow
                If .Cells(X, PartColumnIndex).Value = PartNum Then
                    bExists = True
                    Exit For
                End If
            Next
        End With
        
        ' result
        If bExists = True Then
            MsgBox "Part Number `" & PartNum & "` already exists on Row " & X & vbLf & _
            "Please try again or return to main screen.", vbExclamation
        Else
            With .ListRows.Add
                .Range(, PartColumnIndex) = PartNum
                .Range(, DescrColumnIndex) = MaterialDescription
            End With
            MsgBox "Part Number `" & PartNum & "` added", vbInformation
        End If
        
    End With
End Sub

【讨论】：