Clojure Spec 未正确验证数据

Question

我对 Clojure Spec 感到非常困惑。当我通过输入在 repl 中运行时：

(require '[clojure.spec.alpha :as s])

然后加上：

(s/valid? even? 10)

我得到 //true。当我跑步时：

(s/valid? even? 11)

//错误。好的，这样就可以了。然后，当我在 core.clj 中需要规范时：

(ns spam-problem.core
    (:require [clojure.spec.alpha :as s]
              [clojure.spec.gen.alpha :as gen]))

并尝试一个简单的验证让它抛出一个错误，没有任何反应：

(defn -main
  "I don't do a whole lot ... yet."
  [& args]
  (s/valid? even? 11))

我不知道我在这里做错了什么，并且对规范应该如何工作感到非常困惑。我正在使用命令 lein run 来运行它。是否有其他方式运行它？

Answer 1

我理解你的感受，因为一旦我进入 Spec，它就让我产生了同样的想法。真正帮助我解决我心中的问题的是考虑到 Spec 不是最终的库，而是一个框架。在我的项目中，通常我有一个特殊的模块，其中包含高于基本规范功能的高级包装器。我相信，您可能会这样做：定义一个函数，该函数接受数据、规范并根据您的业务逻辑提出您希望拥有的错误消息。这是我的代码的一个小例子：

(ns project.spec
  (:require [clojure.spec.alpha :as s]))

;; it's better to define that value is a constant
(def invalid :clojure.spec.alpha/invalid)

(defn validate
  "Either returns coerced data or nil in case of error."
  [spec value]
  (let [result (s/conform spec value)]
    (if (= result invalid)
      nil
      result)))

(defn spec-error
  "Returns an error map for data structure that does not fit spec." 
  [spec data]
  (s/explain-data spec data))

现在，让我们准备一些规格：

(defn x-integer? [x]
  (if (integer? x)
    x
    (if (string? x)
      (try
        (Integer/parseInt x)
        (catch Exception e
          invalid))
      invalid)))

(def ->int (s/conformer x-integer?))

(s/def :opt.visits/fromDate ->int)
(s/def :opt.visits/toDate ->int)
(s/def :opt.visits/country string?)
(s/def :opt.visits/toDistance ->int)

(s/def :opt.visits/params
  (s/keys :opt-un [:opt.visits/fromDate
                   :opt.visits/toDate
                   :opt.visits/country
                   :opt.visits/toDistance]))

以下是一些用法示例：

(let [spec :opt.visits/params
      data {:some :map :goes :here}]
  (if-let [cleaned-data (validate spec data)]
    ;; cleaned-data has values coerced from strings to integers,
    ;; quite useful for POST parameters
    (positive-logic cleaned-data)
    ;; error values holds a map that describes an error
    (let [error (spec-error spec data)]
      (error-logic-goes-here error))))

这里可能需要改进的是具有validate 和error 功能的组合功能。这样的函数可以返回两个值的向量：成功标志和结果或错误数据结构，如下所示：

[true {:foo 42}] ;; good result
[false {:error :map}] ;; bad result

Spec 库并不规定单一的数据处理方式；这就是为什么它非常好和灵活。

Answer 2

valid? 是一个返回真或假的谓词。你的程序没有对返回值做任何事情。如果您想抛出异常，请尝试将其打印到控制台或使用s/assert：

如果 (check-asserts?) 在运行时为 false，则始终返回 x。默认为 'clojure.spec.check-asserts' 系统属性的值，否则为 false 放。您可以切换检查断言吗？ with (check-asserts bool)。

所以你可能需要设置(s/check-asserts true) 让s/assert 抛出异常：

(clojure.spec.alpha/assert even? 3)
=> 3
(clojure.spec.alpha/check-asserts?)
=> false
(clojure.spec.alpha/check-asserts true)
=> true
(clojure.spec.alpha/assert even? 3)
ExceptionInfo Spec assertion failed
val: 3 fails predicate: :clojure.spec.alpha/unknown
clojure.core/ex-info (core.clj:4739)