Clojure减速器/地图不工作

Question

我有一个算法如下-

(defn max-of
[args]
(into [] (apply map #(apply max %&) args)))

效果很好。

(max-of [[1 7] [3 5] [7 9] [2 2]]) 返回[7 9]

它基本上找到每个位置上的最大元素。 7 是最大的第一个元素是集合，9 是最大的第二个元素。但是，当尝试从core.reducers 使用reducer/map 时，我得到了

CompilerException clojure.lang.ArityException: Wrong number of args (21) passed to: reducers/map

所以这不起作用-

(defn max-of
[args]
(into [] (apply r/map #(apply max %&) args)))

为什么？

更新

我的最终代码是

(defn max-of [[tuple & tuples]]
  (into [] (r/fold (fn
            ([] tuple)
            ([t1 t2] (map max t1 t2)))
          (vec tuples))))

在上面跑一个快速的板凳给Execution time mean : 626.125215 ms

我有这个我之前写的其他算法 -

(defn max-fold
    [seq-arg]
    (loop [acc (transient []) t seq-arg]
        (if (empty? (first t))
            (rseq (persistent! acc))
            (recur (conj! acc (apply max (map peek t))) (map pop t)))))

它做同样的事情。为此，我得到了 - Execution time mean : 308.200310 ms，它比 r/fold 平行的东西快两倍。任何想法为什么？

顺便说一句，如果我从 r/fold 内容中删除 into []，那么我会得到 Execution time mean : 13.101313 ms。

Answer 1

r/map 采用 [f] 或 [f coll] - 所以你的 apply 方法在这里不起作用

user=> (doc r/map)
-------------------------
clojure.core.reducers/map
([f] [f coll])

对比

user=> (doc map)
-------------------------
clojure.core/map
([f] [f coll] [f c1 c2] [f c1 c2 c3] [f c1 c2 c3 & colls])

Answer 2

为什么这个问题的答案已经给出。那么让我们回答下一个问题：“你想做什么？”

根据我对您的目标的理解（通过元组中的位置找到最大元素）并可能并行执行（当您尝试使用减速器时），这就是您必须做的

(defn max-of [tuples]
  (r/fold (fn
            ([] (first tuples))
            ([t1 t2] (map max t1 t2)))
          ((rest tuples)))

user> (max-of [[1 7] [3 5] [7 9] [2 2]])
(7 9)

(max-of [[1 2 3] [3 2 1] [4 0 4]])
(4 2 4)

user> (max-of [])
nil

user> (max-of [[1 2 3]])
[1 2 3]

解构甚至更好：

(defn max-of [[tuple & tuples]]
  (r/fold (fn
            ([] tuple)
            ([t1 t2] (map max t1 t2)))
          tuples))

更新： 对于大数据，您应该对其进行优化并改用向量

(defn max-of [[tuple & tuples]]
  (r/fold (fn
            ([] tuple)
            ([t1 t2] (map max t1 t2)))
          (vec tuples)))

user> (max-of (repeat 1000000 [1 2 3 4 5 6 7 8 9 10]))
(1 2 3 4 5 6 7 8 9 10)