在cond范围内使用map

Question

我无耻地从我找到的一个示例博文（但现在似乎无法检索）中提取了几乎所有这些代码，该博文演示了使用 Java 的套接字实现来维护一个简单的 IRC 连接。

在玩了一下这个示例时，我遇到了一个问题，我想加入一系列频道。我的第一个想法是在服务器 var 上存储一个通道向量，然后在匹配模式时对其进行解构。然而，这还没有奏效。如果我将地图更改为对 write 函数的裸调用，则一切正常。但是映射写入功能似乎不起作用，我不知道为什么。有趣的是，如果我将地图调用复制并粘贴到运行活动连接的 repl 中，它就可以工作......这是因为这发生在 cond 的范围内吗？裁判可能是罪魁祸首吗？我刚刚进入 Clojure，所以我仍在努力解决问题。

废话不多说，代码如下：

  (ns irc
    (:import (java.net Socket)
            (java.io PrintWriter InputStreamReader BufferedReader)))

  (def server {:server "irc.example.net"
               :port 6667
               :channels ["#a" "#b"]})
  (def client {:realname "Lambda Bot" :nick "lambdabot"})

  (declare conn-handler)


  (defn in [a b]
    (re-find (re-pattern a) b))


  (defn startswith [a b]
    (in (str "^" a) b))


  (defn connect [server]
    (let [socket (Socket. (:server server) (:port server))
          in (BufferedReader. (InputStreamReader. (.getInputStream socket)))
          out (PrintWriter. (.getOutputStream socket))
          conn (ref {:in in :out out})]
      (doto (Thread. #(conn-handler conn server)) (.start))
      conn))


  (defn write [conn msg]
    (println msg)
    (doto (:out @conn)
      (.println (str msg "\r"))
      (.flush)))


  (defn conn-handler [conn server]
    (while (nil? (:exit @conn))
      (let [msg (.readLine (:in @conn))]
        (println msg)
        (cond
          (startswith "ERROR :Closing Link:" msg)
          (dosync (alter conn merge {:exit true}))
          (in " 001 " msg)
          ;; this guy below doesn't seem to work at all
          (map #(write conn (str "JOIN " %)) (:channels server))
          ;; this guy on the other hand seems to work fine
          ;;(write conn (str "JOIN " (first (:channels server))))
          (startswith "PING" msg)
          (write conn (str "PONG " (re-find #":.*" msg)))))))


  (defn login [conn user]
    (write conn (str "NICK " (:nick user)))
    (write conn (str "USER " (:nick user) " 0 * :" (:realname user))))

要运行它，您可以简单地调用：(def irc (connect server))，然后调用 (login irc client)。非常感谢任何帮助！谢谢。

Answer 1

map 是一个惰性操作，即直到需要时才会执行。当从 repl 调用时，repl 会对其进行评估，因为它需要打印返回的值。

你可以使用doall来强制执行惰性操作。

(doall (map ... ))

最好使用doseq 而不是map。 map 用于将一组值转换为另一组值，doseq 用于对一组值执行操作以及您想要执行的操作。

(doseq [ch (:channels server)]
  (write conn (str "JOIN " ch)))