清理其频道地图

Question

假设我们有一个地图m，其结构如下：

{:a (go "a") 
  :b "b" 
  :c "c" 
  :d (go "d")}

如图所示，m 有四个键，其中两个包含通道。

问题：如何编写一个通用函数（或宏？）cleanse-map，它采用类似m 的映射并输出其无通道版本（其中，在这种情况下，应该是{:a "a" :b "b" :c "c" :d "d"})？

这个问题的一个很好的辅助函数可能如下：

(defn chan? [c]
  (= (type (chan)) (type c)))

cleanse-map（或其他任何名称）的返回值本身是否是一个通道也无关紧要。即：

`(cleanse-map m) ;=> (go {:a "a" :b "b" :c "c" :d "d"})

Answer 1

Limitations 的core.async 使得cleanse-map 的实现不是那么简单。但是以下一个应该可以工作：

(defn cleanse-map [m]
  (let [entry-chs (map
                   (fn [[k v]]
                     (a/go
                       (if (chan? v)
                         [k (a/<! v)]
                         [k v])))
                   m)]
    (a/into {} (a/merge entry-chs))))

基本上，这里做了什么：

1. 每个映射条目都被转换为包含该映射条目的通道。如果map entry的值为channel，则在映射函数中的go-block内提取。
2. 带有地图条目的频道是merge-d 为单一频道。完成此步骤后，您将拥有一个包含地图条目集合的频道。
3. 带有地图条目的频道被转换为将包含所需地图的频道（a/into 步骤）。

Answer 2

(ns foo.bar
  (:require
    [clojure.core.async :refer [go go-loop <!]]
    [clojure.core.async.impl.protocols :as p]))

(def m
  {:a (go "a")
   :b "b"
   :c "c"
   :d (go "d")
   :e "e"
   :f "f"
   :g "g"
   :h "h"
   :i "i"
   :j "j"
   :k "k"
   :l "l"
   :m "m"})

(defn readable? [x]
  (satisfies? p/ReadPort x))

(defn cleanse-map
  "Takes from each channel value in m,
   returns a single channel which will supply the fully realized m."
  [m]
  (go-loop [acc {}
            [[k v :as kv] & remaining] (seq m)]
    (if kv
      (recur (assoc acc k (if (readable? v) (<! v) v)) remaining)
      acc)))

(go (prn "***" (<! (cleanse-map m))))

=> "***" {:m "m", :e "e", :l "l", :k "k", :g "g", :c "c", :j" j", :h "h", :b "b", :d "d", :f "f", :i "i", :a "a"}