clojure：为命名空间中的每个函数添加调试跟踪？

Question

刚开始在我的一个家庭项目中使用 log4j，我正准备用鼠标将 (trace (str "entering: " function-name)) 剪切并粘贴到一个大模块中的每个函数中。然后理性的声音出现并说“必须有更好的方法”......我可以想到制作一个包含整个函数块并将跟踪添加到它们的宏或类似的东西？明智的 Stack-overflowing-clojurians 有什么建议吗？

Answer 1

不需要宏：

(defn trace-ns
  "ns should be a namespace object or a symbol."
  [ns]
  (doseq [s (keys (ns-interns ns))
          :let [v (ns-resolve ns s)]
          :when (and (ifn? @v) (-> v meta :macro not))]
    (intern ns
            (with-meta s {:traced true :untraced @v})
            (let [f @v] (fn [& args]
                          (clojure.contrib.trace/trace (str "entering: " s))
                          (apply f args))))))

(defn untrace-ns [ns]
  (doseq [s (keys (ns-interns ns))
          :let [v (ns-resolve ns s)]
          :when (:traced (meta v))]
    (alter-meta! (intern ns s (:untraced (meta v)))
                 #(dissoc % :traced :untraced))))

...或类似的东西。最可能的额外要求是使用filter，以免在不是ifn?s 的事情上调用trace。 更新：在解决方案中进行了编辑（也处理宏）。更新 2：修复了一些主要错误。更新 4：添加了 untrace 功能。

更新 3： 这是我的 REPL 中的一个示例：

user> (ns foo)
nil
foo> (defn foo [x] x)
#'foo/foo
foo> (defmacro bar [x] x)
#'foo/bar
foo> (ns user)
nil
user> (trace-ns 'foo)
nil
user> (foo/foo :foo)
TRACE: "entering: foo"
:foo
user> (foo/bar :foo)
:foo
user> (untrace-ns 'foo)
nil
user> (foo/foo :foo)
:foo