如何从具有 clojure 中键列表的映射列表中找到匹配项

Question

我是 Clojure 的新手。

我有一个地图 s1 和一个向量 s2

(def s1 {:params [{:param  :begin_date
                 :name     "begin date"
                 :dtk      :date
                 :param_operand :single}
                {:param  :begin_num
                 :name     "begin num"
                 :dtk      :numeric
                 :param_operand :single}
                {:param  :begin_num2
                 :name     "begin num2"
                 :dtk      :numeric
                 :biparam_operand :single}]})

(def s2 [:begin_date :begin_num]) 

我正在尝试从 s1 和 s2 中找到匹配项。 IE 遍历 s2 中的每个元素并从 s1 中找到匹配项。 如果匹配存在，请检查 :dtk 的类型，如果类型是 :date 则我们接受该映射。

这是我尝试过的代码，当我必须使用列表 s2 中的一个元素来查找匹配是否存在时 - :begin_date

(defn test->map
  [s1 s2]
  (let [test-vec (->> s1
                      :params
                      (filter (fn [typet] (= (:param typet) :begin_date)))
                      first
                      :dtk)]
    (when (= test-vec :date)
      "done")))

如何修改上述函数，使其能够遍历整个元素列表并找到匹配项。 TIA。

Answer 1

一种使用keep的方法：

(defn match [k]
  (->> s1
       :params
       (keep
        (fn [{:keys [param] :as v}]
          (when (= param k)
            v)))
       first))

或将for 与:when 一起使用：

(defn lookup [k]
  (first
   (for [{:keys [param] :as v} (:params s1)
         :when (= param k)]
     v)))

（这有点类似于您使用for 和filter 的方法。现在只有:when 进行过滤，我返回实际值而不是字符串"done"。）

结果：

(map lookup s2)
;; => ({:param :begin_date, :name "begin date", :dtk :date, :param_operand :single}
;;     {:param :begin_num, :name "begin num", :dtk :numeric, :param_operand :single})

我会亲自将当前数据结构s1 转换为Clojure 映射（例如通过reduce），因此您可以通过键访问参数并使用select-keys。这样您就不必每次查找都遍历整个 s2。

(defn transform [s1]
  (reduce
   (fn [acc {:keys [param] :as v}]
     (assoc acc param v))
   {}
   (:params s1)))

(transform s1)
;; => {:begin_date
;;     {:param :begin_date, :name "begin date", :dtk :date, :param_operand :single},
;;     :begin_num
;;     {:param :begin_num, :name "begin num", :dtk :numeric, :param_operand :single},
;;     :begin_num2
;;     {:param :begin_num2,
;;      :name "begin num2",
;;      :dtk :numeric,
;;      :biparam_operand :single}}

(select-keys (transform s1) s2)
;; => {:begin_date
;;     {:param :begin_date, :name "begin date", :dtk :date, :param_operand :single},
;;     :begin_num
;;     {:param :begin_num, :name "begin num", :dtk :numeric, :param_operand :single}}