f# 中的重载取消引用 (!) 和赋值 (:=) 运算符

Question

我正在尝试重载取消引用 (!) 和赋值 (:=) 运算符，但不是全局的。我仍然想保留通常的 ref op 重载。下面是一些代码来说明问题：

type MyVar<'a>(init:'a) =
    let mutable _value = init
    member __.Get() = _value
    member __.Set x = _value <- x
    //static member (!) (s:MyVar<'a>) = s.Get()      // compiles, doesn't work
    //static member (:=) (d:MyVar<'a>, s) = d.Set(s) // warning, doesn't work

//let inline (!) (x :MyVar<'a>) = x.Get()           // overrides !ref
//let inline (:=) (x :MyVar<'a>) (v :'a) = x.Set(v) // overrides ref := v 
let inline (!!) (x :MyVar<'a>) = x.Get()            // works but ugly
let inline (.=) (x :MyVar<'a>) (v :'a) = x.Set(v)   // works ... meh

let test_myvar() =
    let mv = new MyVar<_>("wee")
    let r = ref 100
    let x = !mv
    let y = !!mv
    let z = !r
    mv .= "haaa"
    r := 42

解决方案：

@Carsten 的解决方案是我一直在寻找和工作的。然而，事实证明，我使用的是 Websharper，它使用引号和 @Carstens 解决方案进行编译，变得有点 more complex。由于 Websharper.UI.Next 包含该解决方案，我只需将其包含在我的项目中，它就可以工作了！

Answer 1

您可以通过重载 (!) 和 (:=) 操作符来使其与 static constraints 一起工作：

type MyVar<'a>(init:'a) =
    let mutable _value = init
    member __.Value with get () = _value and set v = _value <- v

let inline (!) a =
    (^a : (member Value : ^b) a)

let inline (:=) a v =
    (^a : (member Value : ^b with set) (a, v))

我删除了您的访问器，因为我只需要与 Ref<'a> 相同的访问器（但您可以重新添加它们）

演示

这是一个 F# 交互式会话，用您的价值观展示了这一点：

val mv : MyVar<string>
val r : int ref = {contents = 100;}

> !mv;;
val it : string = "wee"
> !r;;
val it : int = 100
> mv := "It works";;
val it : unit = ()
> !mv;;
val it : string = "It works"
> r := 50;;
val it : unit = ()
> !r;;
val it : int = 50

---

备注

我不确定我是否真的会这样做 - 你只会重新发明Ref-cell（作为一个班级）而一无所获，当然对于其他人来说可能很难阅读 - 所以要小心对待。