【问题标题】：Using a regular expression in Perl to list variables from another Perl script在 Perl 中使用正则表达式列出来自另一个 Perl 脚本的变量
【发布时间】：2010-03-01 17:00:23
【问题描述】：

我对如何从 Perl 文件中获取所有标量和数组的想法如下：

open (InFile, "SomeScript.pl");
@InArray = <InFile>;
@OutArray = {};
close (InFile);
$ArrayCount = @InArray;
open (OutFile, ">outfile.txt");
for ($x=0; $x<=$ArrayCount; $x++){
$Testline = @InArray[$x];

if($Testline =~ m/((@|\$)[A-Z]+)/i){
    $Outline = "$1\n";  
    push @OutArray, $Outline;
}
}
print OutFile @OutArray;
close(OutFile);

...这很好用。问题是如果多个变量出现在一行上，它只会抓取第一个变量。一个例子可能是：

$FirstVar = $SecondVar + $ThirdVar;

脚本只会抓取$FirstVar 并输出到文件。这可能仍然有效，因为 $SecondVar 和 $ThirdVar 必须在其他地方初始化，然后继续行有任何意义。我想该规则的例外是同时初始化多个变量的行。

真实 Perl 代码中的示例会破坏这个脚本吗？另外，如何从同一行中获取与我的正则表达式条件匹配的多个项目？

【问题讨论】：

"for my $Testline (@InArray)" 足以循环遍历列表中的元素。此外，不需要显式计算标量 $ArrayCount，因为这是在标量上下文中使用时 @InArray 的值。
你所说的“继续行”是什么意思？
我的意思是前面的例子，或者那段上面的代码 sn-p。以“$FirstVar =". 开头的行

标签： regex perl variables file-io

【解决方案1】：

不要那样做

你不能真正用正则表达式解析 Perl，所以我什至不会尝试。
如果不实际运行它，您甚至无法正确解析它，但您可以使用PPI 接近它。

perl-variables.pl

#! /usr/bin/env perl
use strict;
use warnings;
use 5.10.1;

use PPI;
use PPI::Find;

my($filename) = (@ARGV, $0); # checks itself by default

my $Doc = PPI::Document->new($filename);
my $Find = PPI::Find->new( sub{
  return 0 unless $_[0]->isa('PPI::Token::Symbol');
  return 1;
});

$Find->start($Doc);
while( my $symbol = $Find->match ){
  my $raw = $symbol->content;
  my $var = $symbol->symbol;
  if( $raw eq $var ){
    say $var;
  } else {
    say "$var\t($raw)";
  }
}
print "\n";

my @found = $Find->in($Doc);
my %found;
$found{$_}++ for @found;

say for sort keys %found;

对自己运行它，产生：

$filename
@ARGV
$0
$Doc
$filename
$Find
@_  ($_)
$Find
$Doc
$symbol
$Find
$raw
$symbol
$var
$symbol
$raw
$var
$var
@found
$Find
$Doc
%found
%found  ($found)
$_
@found
%found

$0
$Doc
$Find
$_
$filename
$found
$raw
$symbol
$var
%found
@ARGV
@found

【讨论】：

【解决方案2】：

看起来这会遗漏完全限定的变量名 ($My::Package::Foo) 和用大括号括起来的罕见但有效的变量名 (${variable}、${"varname!with#special+chars"})。您的脚本还将匹配哈希和数组的元素访问（$array[4] ==> $array、$hash{$key} ==> $hash）和对象方法调用（$object->method() ==> $object），其中可能是也可能不是你想要的。

您还使用下划线 ($my_var) 和数字 ($var3) 使变量不匹配，并且您可能会从 cmets、带引号的字符串、pod 等 (# report bugs to bob@company.org) 中得到误报。

匹配多个表达式是使用 /g 修饰符的问题，它将返回匹配列表：

@vars = $Testline =~ /[@\$]\w+/gi;
if (@vars > 0) {
  push @OutArray, @vars;
}

【讨论】：

这些是我从未想过的事情！谢谢！

【解决方案3】：

时间简单的答案是您的正则表达式上的 /g 标志。

复杂的答案是这种代码分析对于 perl 来说是非常困难的。查看模块 PPI 以获得更好、功能更全的 perl 代码语义分析。

【讨论】：

【解决方案4】：

我不能直接回答你的任何一个问题，但我会提供这个：我不知道你为什么要尝试提取标量，但是 perl 附带的调试器包必须“了解”所有变量，我最后一次看它是用 Perl 写的。您最好尝试使用调试器包或从该包中借用的技术来评估 perl 脚本，而不是重新发明轮子。

【讨论】：

【解决方案5】：

尽管方法有限制，这里是上面脚本的一个稍微简单的版本，它从标准输入读取。

#!/usr/bin/perl
use strict;
use warnings;
my %vars;

while (<>) {
  $vars{$_}++ for (m'([$@]\w+)'g);
}

my @vars = keys %vars;
print "@vars\n";

【讨论】：