高级过滤器 VBA

Question

到目前为止，我有此代码，仅适用于工作表 2，如何更改此代码以将多个工作表包含在其中？在这里完成newb。 ：

Sub extractuniquevalues()

    Sheet1.Range("C:C").AdvancedFilter xlFilterCopy, , Sheet4.Range("C1"), True
    Sheet2.Range("C:C").AdvancedFilter xlFilterCopy, , Sheet4.Range("C1"), True

End Sub

Answer 1

你可以这样做：

就地过滤数据：

Sub extractuniquevalues()
    Dim wks As Excel.Worksheet

    For Each wks In Excel.ActiveWorkbook.Worksheets
        Call wks.Range("C:C").AdvancedFilter(XlFilterAction.xlFilterInPlace, , , True)
    Next wks

End Sub

---

过滤数据并将其粘贴到新工作表中：

Sub extractuniquevalues2()
    Dim wks As Excel.Worksheet
    Dim wksSummary As Excel.Worksheet
    '----------------------------------------------------------------------------------

    On Error Resume Next
    Set wksSummary = Excel.ThisWorkbook.Worksheets("Unique data")
    On Error GoTo 0

    If wksSummary Is Nothing Then
        Set wksSummary = Excel.ThisWorkbook.Worksheets.Add
        wksSummary.Name = "Unique data"
    End If


    'Iterate through all the worksheets, but skip [Summary] worksheet.
    For Each wks In Excel.ActiveWorkbook.Worksheets

        With wksSummary

            If wks.Name <> .Name Then
                If Application.WorksheetFunction.CountA(wks.Range("C:C")) Then
                    Call wks.Range("C:C").AdvancedFilter(xlFilterCopy, , .Cells(.Cells(.Rows.Count, 1).End(xlUp).Row + 1, 1), True)
                End If
            End If

        End With

    Next wks

End Sub

每个工作表的唯一数据都打印在名为唯一数据的新工作表的第一列中。

此方法分别过滤来自每个工作表的数据，因此如果 Sheet1 中有值 A，Sheet2 中有值 A，则结果列表中将有两个条目 A。

---

注意，第一个值被认为是一个标题，它可以在结果列表中重复。

Answer 2

我觉得你们的 cmets 保证我把这个作为答案发布，这样我可能会更彻底一点。 这只是为了补充 mielk 提供的答案！

Excel 中的对象层次结构大致概括为“一个 Excel 应用程序拥有工作簿。一个 Excel 工作簿拥有工作表。一个 Excel 工作表拥有范围”。有关该外观的更多信息here。

当您点击一个 Excel 文件打开它时，您实际上是在做两件事：

1. 启动 Excel“应用程序”
2. 打开该“应用程序”将“拥有”的工作簿

当您打开后续 Excel 文件时，Excel 将跳过第一步，只需在已运行的 Excel 应用程序中打开一个工作簿。请注意，这意味着类似于一个工作簿可以有多个工作表一个 Excel 应用程序可以有多个属于它的工作簿。

在 VBA 中有多种方法可以访问这些工作簿。一种方法是使用应用程序的Workbooks 成员，就像您使用Workbook 的Sheets 成员访问工作表一样。通常，尽管您只是想访问用户当前正在编辑/处理的工作簿。为此，您可以使用ActiveWorkbook，只要用户开始处理不同的工作簿，它就会自动为您更新。

另一个您经常想要使用的工作簿是“容纳”您正在运行的代码的工作簿。您可以使用ThisWorkbook 来执行此操作。如果您打开 VBA 编辑器并查看项目查看器，您甚至可以看到对 ThisWorkbook 的引用！如果您希望您的代码仅更新/更改包含它的工作簿，那么 ThisWorkbook 是要走的路。

举个例子：

假设您有一个宏来遍历所有打开的工作簿，并将每个工作簿“拥有”的工作表数量放入“主”工作簿中的某个工作表中。

你可以这样做：

Sub CountThem()
    Dim wb As Workbook
    Dim outputCell As Range
    Dim nextRow As Integer

    nextRow = 1
    For Each wb In Application.Workbooks
        wb.Activate
        ThisWorkbook.Sheets("MySheet").Cells(nextRow, 1).Value = ActiveWorkbook.Sheets.Count
        nextRow = nextRow + 1
    Next
End Sub

您可以将此代码作为模块放入“主”工作簿中。

让我知道这是否可以为您解决问题！ :)