XCopy 到带有提示符和通配符的路径

Question

我想重新利用批处理文件，最新的限制是目标位置的目录具有唯一标识符和描述。我需要提示输入唯一标识符并使​​用通配符绕过描述。例如“\serverB\dest\ID - 描述\DIR1\DIR2\

set DEST="\\serverB\Dest"
set /p UNIQUE ID=Enter ID
echo %UNIQUE_ID%
>NULL xcopy "\\serverA\source\something\file.txt" "%DEST%\%UNIQUE_ID% *\DIR1\DIR2" /i /y

以前我没有这个问题，所以长目录名不是问题。现在我需要绕过最终组件，因为目录在描述中不一致。一旦我通过了具有唯一 ID\Desc 的目录，其余子目录将保持一致。

set DEST="\\serverB\Dest"
set /p UNIQUE ID=Enter ID
echo %UNIQUE_ID%
>NULL xcopy "\\serverA\source\something\file.txt" "%DEST%\%UNIQUE_ID% *\DIR1\DIR2"

我得到了无效的驱动器规格作为错误。

我也不从事 IT 工作或以编码为生，因此请对任何回应保持温和。

Answer 1

您不能在目录名称中使用 File Glob，除非您只是想匹配一个目录名称，这在 Windows 可执行文件中是相当一致的。

相反，您可以使用 FOR 循环来匹配目录名称，使用 File Glob 作为目录名称，然后将其保存到变量中并在您的 XCOPY 命令中使用。

@(
  ECHO OFF
  SETLOCAL
  SET "_Src_FilePath=\\serverA\source\something\file.txt"
  SET "_DstPath_Prefix=\\serverB\Dest"
  SET "_DstPath_Postfix=\DIR1\DIR2"
)

SET /P "_UNIQUE_ID=Enter ID: "
IF NOT DEFINED _UNIQUE_ID (
   ECHO. Exiting, you did not provide a Unique ID!
   GOTO :EOF
)
ECHO.ID Provided: "%_UNIQUE_ID%"

REM Get matching Director(y|ies) and copy file(s):

FOR /F "Tokens=*" %%D IN ('
  DIR /AD /B "%_DstPath_Prefix%\%_UNIQUE_ID% *"
') DO (
  ECHO.Matched Directory: "%%D" - Running Copy to: "%_DstPath_Prefix%\%%D%_DstPath_Postfix%"
  >NULL xcopy "%_Src_FilePath%" "%_DstPath_Prefix%\%%D%_DstPath_Postfix%"
)

Answer 2

您不能在路径中间使用wildcards，它们只能在最后一个路径元素中使用。

要解决这个问题，您可以使用 for /D loop 来解析通配符：

set "DEST=\\serverB\Dest"
:LOOP
set /P UNIQUE_ID="Enter ID: " || goto :LOOP
echo %UNIQUE_ID%
for /D %%D in ("%DEST%\%UNIQUE_ID% *") do (
    > nul xcopy "\\serverA\source\something\file.txt" "%%~D\DIR1\DIR2"
)

还有一些进一步的改变：

• 引用的set 语法已被应用，因此引号不再成为分配值的一部分（见第一行）；
• 一个错字已修正，提示变量名为UNIQUE_ID，但不是UNIQUE ID；
• 演示了如何使用conditional execution检测用户是否在Enter ID提示符中输入了内容；
• Windows 中的 null 设备称为 nul 但不是 null；