从其他txt追加后对txt进行排序的批处理文件

Question

我想要一个批处理文件，我可以将一个文本文件拖到上面（最好是一次多个文本文件），它将逐行读取每个文本文件并将每一行添加到指定的目标文本文件中。目标文本文件将不包含任何重复的行，并将按字母顺序排序。源文件永远不会包含同一行两次，但可能包含非字母数字字符，例如：{ - : _ ~ !

例子：

a.txt:

apple
banana
garbage carrot
{Elmer Fudd}

b.txt

1 tequila
2 tequila
3 tequila
garbage carrot
{Bugs Bunny}

destination.txt 之前：

{daffy duck}
floor

将a.txt和b.txt拖到批处理文件后的destination.txt：

{Bugs Bunny}
{daffy duck}
{Elmer Fudd}
1 tequila
2 tequila
3 tequila
apple
banana
floor
garbage carrot

我已经开始了：

@echo off
setlocal disabledelayedexpansion
set "sourcefile=%~1"
echo "%sourcefile%" > temp.txt
for /f "delims=;" %%F in (%sourcefile%) do (
    echo %%F>>temp.txt
)

del /q destination.txt
ren temp.txt destination.txt

它将文件复制到一个临时文件中，但我不知道如何对其进行排序。排序命令对我不起作用，它只是挂起程序。感谢所有帮助。谢谢！

Answer 1

@echo off
setlocal enabledelayedexpansion
set "prev="
echo "%~1"
copy /y destination.txt+"%~1" temp.txt >nul

(    
for /f "delims=" %%F in ('sort temp.txt') do (
  if "!prev!" neq "%%F" echo(%%F
  set "prev=%%F"
)
)>destination.txt
del temp.txt

应该对你有用（我没试过）

无需使用for /f 处理新文件 - copy a+b c 将 a 和 b 连接到 c 中。如果目的地已经存在，/y 会强制覆盖目的地。

然后处理每一行，如果此行与前一行不匹配，则回显从sort 读取的行 - 但“将字符串括在引号中”，以便批处理知道如果字符串包含空格，则将其作为单个单元处理或其他分隔符。

(...echo ...)>file 格式（重新）使用 echoed 数据创建文件，而不是将数据发送到屏幕。

Answer 2

如果我理解正确，那么这就足够了：

@echo off
:loop
   type "%~1" >>"c:\destination.txt"
   shift 
   if not "%~1"=="" goto :loop
sort < "c:\destination.txt" > "%temp%\random file.txt"
move "%temp%\random file.txt" "c:\destination.txt"

Answer 3

另存为批处理文件。这是一个混合批处理/jscript 文件。文件处理/排序在批处理部分完成。然后，调用javascript部分来消除重复的行。

已编辑 - 适应 cmets

@if (@This==@IsBatch) @then
@echo off
rem **** batch zone *********************************************************

    setlocal enableextensions disabledelayedexpansion

rem If there are no files, nothing to do
    if "%~1"=="" goto endProcess

rem Configure the output final file 
    set "outputFile=destination.txt"
    if not exist "%outputFile%" >"%outputFile%" break

rem Configure and initialize temporary file
    set "tempFile=%temp%\%~nx0.%random%%random%.tmp"
    find /v "" <"%outputFile%" >"%tempFile%"

rem Iterate over the file list sending output to temporary file and deleting input file
    for %%a in (%*) do (
        find /v "" <"%%a" >>"%tempFile%"
        rem del /q "%%a" 2>nul 
    )

rem Process temporary file into outpufile, sorting and eliminating duplicates    
    type "%tempFile%" | sort  | cscript //nologo //e:Javascript "%~f0" > "%outputFile%"

rem Cleanup    
    del /q "%tempFile%" 2>nul

:endProcess 
    endlocal
    exit /b

@end
// **** Javascript zone *****************************************************
    var stdin=WScript.StdIn, stdout=WScript.StdOut, previous=null, current;
    while (!stdin.AtEndOfStream){
        if (previous !== (current=stdin.ReadLine())) stdout.WriteLine(current);
        previous = current;
    };