使用 PERL 获取子目录中所有文件的名称和大小

Question

我编写了一个例程来读取两个文件夹及其所有子文件夹中包含的文件的所有名称和大小。根文件夹名称在命令行参数中提供，每个文件夹都在 for 循环中处理，详细信息将输出到两个文件夹中的每一个的单独文件中。但我发现只有两个根文件夹中文件的文件名/大小被输出，我无法更改到子文件夹并重复该过程，因此子目录中的文件被忽略。调试跟踪显示 chdir 命令从未执行，因此我的评估有问题，但我看不到它是什么。 代码是这样的

#!/usr/bin/perl
#!/usr/local/bin/perl

use strict;
use warnings;

my $dir = $ARGV[0];
opendir(DIR, $dir) or die "Could not open directory '$dir' $!";
my @subdirs = readdir(DIR) or die "Unable to read directory '$dir': $!";

for (my $loopcount = 1; $loopcount < 3; $loopcount = $loopcount + 1) {
    my $filename = 'FileSize_'.$dir.'.txt';
    open (my $fh, '>', $filename) or die "Could not open file '$filename' $!";      
    for my $subdir (sort @subdirs) {
        unless (-d $subdir) {
            # Ignore Sub-Directories in this inner loop
            # only process files
            # print the file name and file size to the output file
            print "Processing files\n";
            my $size = -s "$dir/$subdir";
            print $fh "$subdir"," ","$size\n";
        }
        elsif (-s "$dir/$subdir") {
        # We are here because the entry is a sub-folder and not a file
        # if this sub-folder is non-zero size, i.e has files then
        # change to this directory and repeat the outer for loop
            chdir $subdir;
            print "Changing to directory $subdir\n";
            print "Processing Files in $subdir\n";
        };
    }
    # We have now processed all the files in First Folder and all it's subdirecorries
    # Now assign the second root directory to the $dir variable and repeat the loop
    print "Start For Next Directory\n";
    $dir = $ARGV[1];
    opendir(DIR, $dir) or die "Could not open directory '$dir' $!";
    @subdirs = readdir(DIR) or die "Unable to read directory '$dir': $!";;
}
exit 0;

命令行调用是“perl FileComp.pl DiskImage DiskImage1” 但只输出根 DiskImage 和 DiskImage1 文件夹中文件的文件名和文件大小，忽略子文件夹中的所有文件。 永远不会满足更改为“elseif”条件的代码并且永远不会执行代码，因此那里存在错误。 提前感谢您的任何建议。

Answer 1

此检查很可能总是错误的，因为您正在查看错误的内容。

   unless (-d $subdir) {

$subdir 是$dir 中的文件或目录的文件名，因此要访问它，您需要使用$dir/$subdir 的完整相对路径，就像您在这里所做的那样：

        my $size = -s "$dir/$subdir";

如果您确实修复了unless 检查，您也会遇到问题，因为在阅读$dir 的内容期间执行chdir 也会导致问题，因此将在看到$dir/$subdir 的后续实例的位置错误。

Answer 2

在不更改目录的情况下执行这样的逻辑要容易得多，但是如果您确实使用 File::chdir 或 File::pushd 以便在退出该范围时返回到上一个目录。但是，通过使用像 Path::Iterator::Rule 这样处理子目录逻辑的递归迭代器来解决这个问题要容易得多：

use strict;
use warnings;
use Path::Iterator::Rule;
use Path::Tiny;

my $rule = Path::Iterator::Rule->new->not_directory;
foreach my $dir (@ARGV) {
    my $fh = path("FileSize_$dir.txt")->openw;
    my $next = $rule->iter($dir);
    while (defined(my $item = $next->())) {
        my $size = -s $item;
        print $fh "$item $size\n";
    }
}

或者，您可以使用visitor 回调，它会同时传递每个项目的完整路径（用于文件操作）和基本名称：

my $rule = Path::Iterator::Rule->new->not_directory;
foreach my $dir (@ARGV) {
    my $fh = path("FileSize_$dir.txt")->openw;
    $rule->all($dir, {visitor => sub {
        my ($path, $basename) = @_;
        my $size = -s $path;
        print $fh "$basename $size\n";
    }});
}