如何删除列表框中的水平滚动条？

Question

我正在尝试摆脱列表框中的水平滚动条 - 当用户单击某些单元格时出现，然后每次用户单击该单元格时都会“删除”（所以我不能手动更改它，我必须用代码更改它）--但 .ColumnWidths 属性似乎不起作用。

似乎 ColumnWidths 默认设置为 74——这是基于这样一个事实，即如果我将 Width 设置为 74 或更大，则没有水平滚动条。

如果单击单元格时，我进入设计模式，打开属性，我可以手动将 ColumnWidths 设置为 35。这不是解决方案，因为我的列表框是根据用户的活动单元格创建和删除的。尽管如此，这证实了我的代码是如何编写的。

Option Explicit
 
Private WithEvents Lbx As MSForms.ListBox
Private oTarget As Range
Private ListBoxName As String
Private Const Cell_A1 As String = "B1:B20" 'change addr as required.


Private Sub Lbx_Change()
 
    Dim k As Long
    
    oTarget.ClearContents
    
    For k = 0 To Lbx.ListCount - 1
        If Lbx.Selected(k) Then
            If Len(oTarget) = 0 Then
                oTarget = Lbx.List(k)
            Else
                oTarget = _
                Trim(oTarget & vbNewLine & Lbx.List(k))
            End If
        End If
    Next

End Sub


Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    
    Dim oListBox As OLEObject

    On Error Resume Next
    Me.OLEObjects(1).Delete
    
    Range(Cell_A1).Interior.ColorIndex = 0
    
    If Target.Column = 2 And (Target.Row >= 1 And Target.Row <= 20) Then
    'UCase(Target.Address(0, 0)) = UCase(Cell_A1)
        Application.DisplayFormulaBar = False
        Set oListBox = _
        Me.OLEObjects.Add(ClassType:="Forms.ListBox.1")
        With oListBox
             Names.Add "ListBoxName", .Name
            .Left = Target.Offset(0,1).Left
            .Top = Target.Offset(0, 0).Top
            .ColumnCount = 1
            .ColumnWidths = "35"
            .Width = 54
            .Height = Me.StandardHeight * 16
            .Object.ListStyle = fmListStylePlain
            .ListFillRange = "A1:A20"
            .Placement = xlFreeFloating
            .Object.MultiSelect = fmMultiSelectMulti
            .Object.SpecialEffect = fmSpecialEffectFlat
            .Object.BorderStyle = fmBorderStyleSingle
            With Application
                .OnTime Now + _
                TimeSerial(0, 0, 0.01), Me.CodeName & ".Hooklistbox"
                .CommandBars.FindControl(ID:=1605).Execute
            End With
        End With
    Else
        Application.DisplayFormulaBar = True
        Names("ListBoxName").Delete
        Range(Cell_A1).Interior.ColorIndex = 0
    End If
 
End Sub
 

Private Sub Hooklistbox()
 
    Application.CommandBars.FindControl(ID:=1605).Reset
    Set oTarget = ActiveCell
    ActiveCell.Interior.Color = vbGreen
    'display the listbox and hook it.
    With Me.OLEObjects(Evaluate("ListBoxName"))
        .Visible = True
        Set Lbx = .Object
    End With
    
End Sub

Answer 1

类型

.Object.

在 .ColumnCount 和 .ColumnWidths 之前 然后摆脱 on error resume next，它首先将您带到了这个“隐藏”错误 在不再需要时使用 on error goto 0

++ 而不是：

On Error Resume Next
    Me.OLEObjects(1).Delete

你可以使用：

If Me.OLEObjects.Count > 0 Then Me.OLEObjects(1).Delete

并删除这一行（因为名称会被覆盖，所以不需要删除：

 Names("ListBoxName").Delete