SQL Server 动态 SQL - 从表列表中获取输出

Question

我正在尝试遍历包含表名列表的临时表变量。我想简单地计算每个表中 DateTracked 列大于 30 天的行。我无法动态更改 FROM @tblName 变量以存储记录数，然后将其插入到我的跟踪表中。最终我将使用一个游标来遍历每个，但我只想先为单个表获取这个逻辑。这是我的测试代码：

DECLARE @tblName as NVARCHAR(MAX)
DECLARE @q as NVARCHAR(MAX)
SET @q = 'Select Count(DateTracked) FROM Audit.' + @tblName + ' WHERE DateTracked > DATEADD(dd, -30, CAST(GETDATE() as date))'

--DECLARE @tblNameTable TABLE
--(
--  tableName NVARCHAR(MAX)
--)
--INSERT INTO @tblNameTable VALUES (N'myTestTable')

DECLARE @ExpectedRecordsToMove AS TABLE (col1 int)
INSERT INTO @ExpectedRecordsToMove EXECUTE sp_executesql @q, N'@tblName nvarchar(500)', @tblName = 'myTestTable'

SELECT * FROM @ExpectedRecordsToMove

Answer 1

找到解决方案。

DECLARE @tblName as NVARCHAR(MAX) = 'tblAutoDispatch_DispatchStatus_Map_Tracking'
DECLARE @q as NVARCHAR(MAX) = 'SELECT Count(DateTracked) FROM Audit.' + @tblName + ' WHERE DateTracked > DATEADD(dd, -30, CAST(GETDATE() as date))'

DECLARE @ExpectedRecordsToMove TABLE
(
    ExpectedRecordsToMove Int
)
INSERT INTO @ExpectedRecordsToMove
EXECUTE sp_executesql @q

SELECT * FROM @ExpectedRecordsToMove

_{注意：OP 就问题提供的答案。}

Answer 2

sp_executesql 也允许输出参数。可以在内部查询中分配变量并返回值。

DECLARE @tblName AS NVARCHAR(MAX) = N'tblAutoDispatch_DispatchStatus_Map_Tracking';
DECLARE @q AS NVARCHAR(MAX)
    = N'SELECT @rowcount = COUNT(DateTracked) FROM Audit.' + @tblName
      + N' WHERE DateTracked > DATEADD(dd, -30, CAST(GETDATE() as date))';

DECLARE @rowcount INT;

EXECUTE sp_executesql
    @query = @q,
    @parameters = N'@rowcount INT OUTPUT',
    @rowcount = @rowcount OUTPUT;

SELECT
    @rowcount;

Answer 3

您实际上可以在没有光标的情况下执行此操作，只需一次构建查询

• 您必须使用QUOTENAME 以确保表名不会导致语法错误
• 您不能参数化表名，它必须直接插入到动态 SQL 中

DECLARE @tablenames TABLE (schemaName sysname, tblName sysname);
--  insert schema and table names

DECLARE @sql nvarchar(max) = N'
SELECT
    ISNULL(tblName, ''Grand Total'') AS tblName,
    SUM(rowcount) AS rowcount
FROM (
' +
(
  SELECT STRING_AGG(CAST(
N'    SELECT ' + QUOTENAME(tn.schemaName, '''') + N'.' + QUOTENAME(tn.tblName, '''') + N' AS tblName,
           Count(DateTracked) AS rowCount
    FROM ' + QUOTENAME(tn.schemaName) + N'.' + QUOTENAME(tn.tblName) + N'
    WHERE DateTracked > DATEADD(dd, -30, CAST(GETDATE() as date))'
  AS nvarchar(max)), N'
UNION ALL
')
  FROM @tablenames tn
  JOIN sys.tables t ON tn.schemaName = SCHEMA_NAME(t.schema_id) AND tn.tblName = t.name
) + N'
) AS tables
GROUP BY ROLLUP(tblName);
';

PRINT @sql;  -- for testing
EXEC (@sql);

• 如果您的 SQL Server 版本上没有STRING_AGG，则必须改用FOR XML