perl 比较两个文件并打印匹配的行

Question

我有这个脚本，它比较两个文件并打印出差异结果。现在我想更改脚本而不是打印出差异行，我想打印匹配的行。并计算每次运行脚本时匹配的时间。请问有人可以给我一个建议吗？谢谢！

#! /usr/local/bin/perl 
# compare 
my $f1 = "/opt/test.txt";
my $f2 = "/opt/test1.txt";
my $outfile = "/opt/final_result.txt";
my %results = (); 
open FILE1, "$f1" or die "Could not open file: $! \n";
while(my $line = <FILE1>){   $results{$line}=1;
}
close(FILE1); 
open FILE2, "$f2" or die "Could not open file: $! \n";
while(my $line =<FILE2>) {  
$results{$line}++;
}
close(FILE2);  
open (OUTFILE, ">$outfile") or die "Cannot open $outfile for writing \n";
foreach my $line (keys %results) { print OUTFILE $line if $results{$line} == 1;
}
close OUTFILE;

Answer 1

print OUTFILE $line if $results{$line} == 1;

这将打印只出现一次的行。

print OUTFILE $line if $results{$line} > 1;

一个小改动（== 到 >），现在它将打印出现多次的行。那应该打印相同的重复行。

哦，如果您想要计数，只需执行以下操作：

if ( $results{$line} > 1 ) {
    print OUTFILE "$results{$line}: ", $line;
}

---

我在这里写了一个更简洁、更灵活的版本。它采用可选文件名并打印到 STDOUT。

您可以用0 代替其中一个名称，以将其中一个文件与另一个文件进行比较。使用 shell 重定向将其保存到文件中。

用法：

$ script.pl file1.txt file2.txt > outfile.txt

代码：

use strict;
use warnings;
use autodie;

my $f1 = shift || "/opt/test.txt";
my $f2 = shift || "/opt/test1.txt";
my %results;
open my $file1, '<', $f1;
while (my $line = <$file1>) { $results{$line} = 1 }
open my $file2, '<', $f2;
while (my $line = <$file2>) { $results{$line}++ }
foreach my $line (sort { $results{$b} <=> $results{$a} } keys %results) {
    print "$results{$line}: ", $line if $results{$line} > 1;
}

Answer 2

这不是最干净的做事方式……但已经完成了艰苦的工作。反转逻辑使其打印所有unless $results{$line} == 1 或if $results{$line} != 1。

添加计数：

print OUTFILE "Count: $results{$line} - $line" if $results{$line} != 1;

或者，您可以使用 grep 过滤掉不需要的内容，完全避免 if 条件：

foreach my $line ( grep { $results{$_} != 1 } keys %results ) {

    print OUTFILE "Count: $results{$line} - $line";
}

Answer 3

试试 Test::Differences。有关代码示例以及输出的外观，请参见此处：

http://metacpan.org/pod/Test::Differences